album_view.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
''===================================================================
'= ASP FILENAME	: /album/album_view.asp
'= CREATED TIME : 2006-5-5
'= LAST MODIFIED: 2006-5-5
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 浏览相片
'= Change Log:
'==================================================================='
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./album_inc.asp" -->
<!-- #include file = "../inc/logic/logic_album.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "album/album_view.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "浏览相片"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowAlbumCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_objRS			'== 记录集
Dim TAG_strPageNav		'== 翻页导航条
Dim TAG_objDicUnit		'== 单列记录
Dim TAG_strVerifyCode	'== 表单校验
Dim TAG_intLastId		'== 上一张相片ID
Dim TAG_intNextId		'== 下一张相片ID
Dim TAG_intAlbumId	    '== 当前相片ID

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)
 

'== 页面析构
Call ActionOver()
%>


<%
''===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'==================================================================='
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_album_view.html.asp" --> 
<%
End Function

''===================================================================
'= Sub         : ShowAlbumCtl()
'= Time		   : Created At 2006-5-5
'= Input       : 
'= Description : 浏览相片
'==================================================================='
Function ShowAlbumCtl()
	Dim intAlbumId,intLastId,intNextId,strSql

	'== 服务器端数据校验
	If Not ServerDataCheck(arrAlbumViewDataChk) Then Exit Function

	'== 取本相片记录
	intAlbumId = FmtFormData(Request.QueryString("intAlbumId"))
	If Not GetAlbumLogic(intAlbumId) Then
		Exit Function
	End If

	Set TAG_objDicUnit = GBL_objPubDB.GetRsOneRow() 

	If TAG_objDicUnit.Exists("Exist") Then

		'== 图片地址
		TAG_objDicUnit.Item("ALBUM_IMG_URL") = GetAlbumFileUrlLogic(GBL_objPubDB.objPubRS("ALBUM_IMG_FILE"),GBL_objPubDB.objPubRS("ALBUM_STATUS"))

		'== 记浏览数
		Call RecordCounter("CLASS_ALBUM","ALBUM_HITS",1," AND ALBUM_ID=" & intAlbumId )

		'== 取上一张和下一张的ID
		Call GetLastNextAlbumIdLogic(intAlbumId,intLastId,intNextId)
		If intLastId = 0 Then
			TAG_intLastId = intAlbumId
		Else
			TAG_intLastId = intLastId
		End If

		If intNextId = 0 Then
			TAG_intNextId = intAlbumId
		Else
			TAG_intNextId = intNextId
		End If

		'== 赋ID
		TAG_intAlbumId = intAlbumId

		Dim strFileName 
		Dim intMaxPerPage
		Dim intCurPage,intTotalPut

		intMaxPerPage = GBL_intMaxPerPage
		TAG_intPerPage = intMaxPerPage

		strFileName = "album_view.asp?intAlbumId=" & intAlbumId

		'== 取本相片评论记录
		strSql = " AND ALBUM_REVIEW_PHOTO_ID=" & intAlbumId
		If Not GetAlbumReviewsLogic(strSql) Then Exit Function


		Set TAG_objRS = GBL_objPubDB.objPubRS

		intTotalPut = GBL_objPubDB.intRSNum

		intCurPage = GetCurPage(intMaxPerPage,intTotalPut)

		If intCurPage > 1 Then		
			If (intCurPage - 1) * intMaxPerPage < intTotalPut Then
				GBL_objPubDB.objPubRS.Move  (intCurPage - 1) * intMaxPerPage
				Dim BookMark
				BookMark = GBL_objPubDB.objPubRS.BookMark	
			End If
		End If
		
		TAG_strPageNav = ShowPageNav(intTotalPut,intMaxPerPage,intCurPage,strFileName)

		'== 发相片评论客户段表单校验生成
		Dim objClientChk
		Set objClientChk = New classClientChk
		TAG_strVerifyCode = objClientChk.ClientDataCheck("theform",arrAddAlbumReviewDataChk)
		Set objClientChk = Nothing
	End If

End Function
%>