address_userinfo_pop.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
'===================================================================
'= ASP FILENAME	: /address/address_userinfo_pop.asp
'= CREATED TIME : 2006-5-6
'= LAST MODIFIED: 2006-5-6
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 弹出窗口显示用户信息
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../inc/inc_ubb.asp" -->
<!-- #include file = "./address_inc.asp" -->
<!-- #include file = "../inc/logic/logic_user.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "user/address_userinfo_pop.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "查看显示用户信息"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowPopUserInfoCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_objDicUnit		'== 单列记录


'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()
%>

<%
''===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'==================================================================='
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_user_pop_show.html.asp" --> 
<%
End Function

''===================================================================
'= Function    : ShowPopUserInfoCtl()
'= Time		   : Created At 2006-5-6
'= Input       : None
'= Description : 用户个人信息
'==================================================================='
Function ShowPopUserInfoCtl()
	Dim strSql,intUserId,strTmp,arrTmp

	'== 服务器端数据校验
	If Not ServerDataCheck(arrShowUserPopDataChk) Then Exit Function

	'== 取用户信息
	intUserId = FmtFormData(Request.QueryString("intUserId"))
	strSql = " AND USER_ID=" & intUserId
	If Not GetUserLogic(strSql) Then Exit Function

	'== 赋模块标签
	Set TAG_objDicUnit = GBL_objPubDB.GetRsOneRow() 

	'== 其他标签赋值
	If TAG_objDicUnit.Exists("Exist") Then
		'== 签名图
		If GBL_objPubDB.objPubRS("USER_FACE_SELECT") = "QQ秀" Then
			TAG_objDicUnit.Item("USER_QQ_SHOW") = "<img src='" & MakeQQShow(GBL_objPubDB.objPubRS("USER_QQ")) & "'  title='" & GBL_objPubDB.objPubRS("USER_REALNAME") & "的签名图'>"
		Else
			TAG_objDicUnit.Item("USER_QQ_SHOW") = MakeImg( GBL_objPubDB.objPubRS("USER_NOW_FACE")& " onload='javascript:DrawImage(this," & GBL_strUserFaceWidth & "," & GBL_strUserFaceHeight & ",1);'",GBL_objPubDB.objPubRS("USER_REALNAME") & "的签名图")
		End If

		'== 生肖/星座
		TAG_objDicUnit.Item("USER_ANIMAL") = DisplayBirthAnimal(GBL_objPubDB.objPubRS("USER_BIRTH"),strTmp)
		TAG_objDicUnit.Item("USER_CON") = Constellation(GBL_objPubDB.objPubRS("USER_BIRTH"),strTmp)

		'== 身份
		Select Case GBL_objPubDB.objPubRS("USER_AUTHEN")
			Case	0	: strTmp = "普通成员"
			Case	1	: strTmp = "管理员"
			Case	2	: strTmp = "副管理员"
			Case	3	: strTmp = "未通过认证的新用户"
			Case	4	: strTmp = "锁定用户"
			Case	Else : strTmp = "不明用户"
		End Select
		TAG_objDicUnit.Item("USER_AUTH") = strTmp

		'== 签名档
		strTmp = ""
		If GBL_objPubDB.objPubRS("USER_INFO") <> "" And GBL_objPubDB.objPubRS("USER_INFO") <> CONST_DIVIDER Then
			arrTmp = Split(GBL_objPubDB.objPubRS("USER_INFO"),CONST_DIVIDER)
			If Isarray(arrTmp) Then
				strTmp = UbbCode(arrTmp(0))
			Else
				strTmp = "未填"
			End If
		Else
			strTmp = "未填"
		End If
		TAG_objDicUnit.Item("USER_SIGN") = strTmp
	End If

End Function
%>