admin_user_detail.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
'===================================================================
'= ASP FILENAME	: /admin/admin_user_detail.asp
'= CREATED TIME : 2006-4-30
'= LAST MODIFIED: 2006-4-30
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用户详细信息
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/admin/include_admin_action_view.asp" -->
<!-- #include file = "./admin_inc.asp" -->
<!-- #include file = "../inc/logic/logic_user.asp" -->
<!-- #include file = "../inc/inc_ubb.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "admin/admin_user_detail.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "用户详细信息"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "UserDetailCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_objDicUnit

'== 请求校验与过滤
Call ActionViewFilterAdmin(CONST_PAGE_FILE,CONST_ACTION_FUNC)


'== 页面析构
Call ActionOver()
%>

<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_a/page_admin_user_detail.html.asp" -->
<%
End Function

'===================================================================
'= Function	   : UserDetailCtl()
'= Time		   : Created At 2006-5-2
'= Input       : None

'= Description : 用户详细信息
'===================================================================
Function UserDetailCtl()
	Dim intUserId,intSms,intNewSms,strTmp,arrTmp

	'== 服务器端数据校验
	If Not ServerDataCheck(arrGetUserDetailChk) Then Exit Function

	'== 获取ID参数
	If Not GetPostIdValue("intUserId","用户",intUserId) Then Exit Function

	'== 取短信数
	If Not GetUserSmsNumLogic(intUserId,intSms) Or Not GetUserNewSmsNumLogic(intUserId,intNewSms) Then Exit Function

	If Not GetUserLogic(" AND USER_ID=" & intUserId) Then Exit Function

	If Not ResultExecute(GBL_objPubDB.intRSNum,"该用户","ES_DB_NO") Then
		Set TAG_objDicUnit = GBL_objPubDB.GetRsOneRow()
		'== 签名图
		If GBL_objPubDB.objPubRS("USER_FACE_SELECT") = "QQ秀" Then
			TAG_objDicUnit.Item("USER_QQ_SHOW") = "<img src='" & MakeQQShow(GBL_objPubDB.objPubRS("USER_QQ")) & "'  title='" & GBL_objPubDB.objPubRS("USER_REALNAME") & "的签名图'>"
		Else
			TAG_objDicUnit.Item("USER_QQ_SHOW") = MakeImg( GBL_objPubDB.objPubRS("USER_NOW_FACE")& " onload='javascript:DrawImage(this," & GBL_strUserFaceWidth & "," & GBL_strUserFaceHeight & ",1);'",GBL_objPubDB.objPubRS("USER_REALNAME") & "的签名图")
		End If

		'== 短信
		TAG_objDicUnit.Item("USER_SMS") = intSms
		TAG_objDicUnit.Item("USER_NEW_SMS") = intNewSms

		'== 生肖/星座
		TAG_objDicUnit.Item("USER_ANIMAL") = DisplayBirthAnimal(GBL_objPubDB.objPubRS("USER_BIRTH"),strTmp)
		TAG_objDicUnit.Item("USER_CON") = Constellation(GBL_objPubDB.objPubRS("USER_BIRTH"),strTmp)

		'== 身份
		TAG_objDicUnit.Item("USER_AUTH") = GetUserAuthLogic(GBL_objPubDB.objPubRS("USER_AUTHEN"))

		'== 签名档
		strTmp = ""
		If GBL_objPubDB.objPubRS("USER_INFO") <> "" And GBL_objPubDB.objPubRS("USER_INFO") <> CONST_DIVIDER Then
			arrTmp = Split(GBL_objPubDB.objPubRS("USER_INFO"),CONST_DIVIDER)
			If Isarray(arrTmp) Then
				strTmp = UbbCode(arrTmp(0))
			Else
				strTmp = "未填"
			End If
		Else
			strTmp = "未填"
		End If
		TAG_objDicUnit.Item("USER_SIGN") = strTmp
	End If
End Function
%>