admin_login.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
'===================================================================
'= ASP FILENAME	: /admin/admin_login.asp
'= CREATED TIME : 2006-4-30
'= LAST MODIFIED: 2006-4-30
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 系统登陆
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/admin/include_admin_action_execute.asp" -->
<!-- #include file = "./admin_inc.asp" -->
<!-- #include file = "../inc/logic/logic_admin.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "admin/admin_login.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "系统登陆"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ManageLoginCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 请求校验与过滤
Call ActionExecFilterAdmin(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()
%>

<%
'=============== FUNCTION BODY BEGIN ===============================
'===================================================================
'= Function		: ManageLoginCtl()  
'= Time		    : Created At 2006-5-1
'= Input        : None
'= Output       : None
'= Description  : 系统登陆
'===================================================================
Function ManageLoginCtl()
	Dim strErrInfo,intErrId,strAlert

	'== 服务器端数据校验
	If Not ServerDataCheck(arrAdminLoginDataChk) Then Exit Function
 
	'== 数据获取
	Call CnvFormData(strAdminLoginFormName,GBL_objFormData)

	'== 逻辑处理		
	If Not AdminLoginLogic(GBL_objFormData) Then	
		intErrId = GBL_objException.getErrId()
		strErrInfo = GBL_objException.getErrInfo()
		GBL_objException.errReset()
		Call ActionOver()
		strAlert = "<script language=""JavaScript"" type=""text/JavaScript"">alert(""" & intErrId & ": " & strErrInfo & """);window.location.href=""admin_index.asp"";</script>"
		Response.Write strAlert
		Response.end
		Exit Function
	End If
	
	'== 改变成功提示方式
	GBL_intSuccType = 2

	'== 成功处理
	Dim strHtmlCode,strSuccUrl
	strHtmlCode = "管理员登陆成功"
	strSuccUrl = "admin/admin_home.asp"
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function
%>