admin_user_manage.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
''===================================================================
'= ASP FILENAME	: /admin/admin_user_manage.asp
'= CREATED TIME : Feb,08,2004
'= LAST MODIFIED: Feb,08,2004
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用户管理
'= Change Log:
'==================================================================='
%>

<!-- #include file = "../inc/admin/include_admin_action_view.asp" -->
<!-- #include file = "./admin_inc.asp" -->
<!-- #include file = "../inc/logic/logic_user.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "admin/admin_user_manage.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "用户管理"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowUserCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_objRS			'== 列表记录集
Dim TAG_strPageNav		'== 翻页导航


'== 请求校验与过滤
Call ActionViewFilterAdmin(CONST_PAGE_FILE,CONST_ACTION_FUNC)


'== 页面析构
Call ActionOver()
%>

<%
''===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'==================================================================='
Function LoadPageTpl()
%>
	<!-- #include file = "../template_a/page_admin_user_list.html.asp" -->
<%
End Function

''===================================================================
'= Function	   : ShowUserCtl()
'= Time		   : Created At June,8,2003
'= Input       : None
'= Description : Show the user list by page
'==================================================================='
Function ShowUserCtl()
	Dim strFileName 
	Dim intMaxPerPage
	Dim intCurPage,intTotalPut
	Dim strAccount,strRealName,strQq,strEmail,strWork,strWorkShop,strTele,strClass,strSex,strEnroll
	Dim strSql,intAuthen
	Dim strUrl

	intMaxPerPage = GBL_intMaxPerPage
	TAG_intPerPage = GBL_intMaxPerPage

	strAccount = Request("iptAccount")
	strRealName = Request("iptRealName")
	strEmail = Request("iptEmail")
	strWork = Request("iptWork")
	strWorkShop = Request("iptWorkShop")
	strTele = Request("iptTele")
	strClass = Request("iptClass")
	strSex = Request("selSex")
	intAuthen = Request("selAuthen")

	strSql = SearchQueryFmt(arrUserSearch)

	If strAccount <> "" Then
		strUrl = strUrl & "&iptAccount=" & strAccount
	End If

	If strRealName <> "" Then
		strUrl = strUrl & "&iptRealName=" & strRealName
	End If

	If strEmail <> "" Then
		strUrl = strUrl & "&iptEmail=" & strEmail
	End If

	If strWork <> "" Then
		strUrl = strUrl & "&iptWork=" & strWork
	End If

	If strWorkShop <> "" Then
		strUrl = strUrl & "&iptWorkShop=" & strWorkShop
	End If

	If strTele <> "" Then
		strUrl = strUrl & "&iptTele=" & strTele
	End If

	If strSex <> "" Then
		strUrl = strUrl & "&selSex=" & strSex
	End If

	If strEnroll <> "" Then
		strUrl = strUrl & "&iptEnroll=" & strEnroll
	End If

	If strClass <> "" Then
		strUrl = strUrl & "&iptClass=" & strClass
	End If

	If intAuthen <> "" Then
		strUrl = strUrl & "&selAuthen=" & intAuthen
	End If

	strFileName = "admin_user_manage.asp?method=ShowUser" & strUrl
	
	'== 取用户记录集
	If Not GetUsersLogic(strSql) Then Exit Function

	If Not ResultExecute(GBL_objPubDB.intRSNum,"该用户列表","ES_DB_NO") Then

		Set TAG_objRS = GBL_objPubDB.objPubRS
	
		intTotalPut = GBL_objPubDB.intRSNum

		intCurPage = GetCurPage(intMaxPerPage,intTotalPut)
		
		If intCurPage > 1 Then		
			If (intCurPage - 1) * intMaxPerPage < intTotalPut Then
				GBL_objPubDB.objPubRS.Move  (intCurPage - 1) * intMaxPerPage
				Dim BookMark
				BookMark = GBL_objPubDB.objPubRS.BookMark	
			End If
		End If
		
		TAG_strPageNav = ShowPageNav(intTotalPut,intMaxPerPage,intCurPage,strFileName)

	End If
End Function
%>