online_frame.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
'===================================================================
'= ASP FILENAME	: /online_frame.asp
'= CREATED TIME : 2006-6-27
'= LAST MODIFIED: 2006-6-27
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 在线人数 
'= Change Log:
'===================================================================
%>
<!-- #include file = "./inc/customer/include_customer_action_view.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "online_frame.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "在线人数"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "ShowOnlineCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "./"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_strVerifyCode

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)
 
'== 页面析构
Call ActionOver()

%>

<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "./template_c/page_online.html.asp" -->
<%
End Function

'=====================================================================
'= Function     : ShowOnlineCtl()
'= Time		    : Created At 2006-6-27
'= Input        : None
'= Output       : None
'= Return       : 
'= Description  : 在线人数
'=====================================================================
Function ShowOnlineCtl()

	'== Get now online member
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ONLINE"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "DISTINCT(ONLINE_USER),ONLINE_USER_ID",""
	GBL_objPubDB.Where = "ONLINE_USER_AUTHEN<>3"
	GBL_objPubDB.SQLRSExecute()
	Call ResultExecute(GBL_objPubDB.intErrNum,"get online user","ES_ERR")
	Dim intOnlineUser : intOnlineUser = GBL_objPubDB.intRSNum

	Dim clsTable,i,strHtmlCode
	Set clsTable = New classTable
	'== Set table prameters
	clsTable.Clear()
	clsTable.Border = "0"
	clsTable.CellPadding = "2"
	clsTable.CellSpacing = "1"
	clsTable.Width = "90%"
	clsTable.ClassType = ""
	clsTable.Align = "center"
	clsTable.OutFlag = 2
	clsTable.MakeTable()

	clsTable.AddTitleTr "CSS_TD_CENTER3" 
	clsTable.AddTitleTd "", "CSS_TD_CENTER3" ,"100%"

	For i = 1 To intOnlineUser
		clsTable.AddTr ""
		strHtmlCode = MakeLinkClew("#",GBL_objPubDB.objPubRS("ONLINE_USER"),"查看详细信息"," onclick=window.open('" & GBL_strHomeURL & "address/address_userinfo_pop.asp?intUserId=" & GBL_objPubDB.objPubRS("ONLINE_USER_ID") & "','','left=5,top=5,width=450,height=410,scrollbars=yes,status=yes');")
		clsTable.AddTd strHtmlCode,"CSS_TD_CENTER3" 
		GBL_objPubDB.objPubRS.MoveNext
	Next

	

	ShowOnlineCtl = clsTable.OutPutTable()
	
	Set clsTable = Nothing

End Function
%>