adbpnfed.pas

来自「delphi编程控件」· PAS 代码 · 共 337 行

unit adbpnfed;
(*
 COPYRIGHT (c) RSD software 1997 - 98
 All Rights Reserved.
*)

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Menus, StdCtrls, ComCtrls, adbpanel;

type
  TAutoPanelFieldsEditor = class(TForm)
    BHelp: TButton;
    BCancel: TButton;
    BOk: TButton;
    GB: TGroupBox;
    ColumnList: TListBox;
    NewButton: TButton;
    DeleteButton: TButton;
    AddAllFields: TButton;
    DeleteAll: TButton;
    FontDialog: TFontDialog;
    PM: TPopupMenu;
    Newcolumn1: TMenuItem;
    Deletecolumn1: TMenuItem;
    Addallfields1: TMenuItem;
    Deleteallcolumns1: TMenuItem;
    ts1: TGroupBox;
    ColAlignment: TComboBox;
    ColColor: TComboBox;
    LFieldName: TLabel;
    ColFieldName: TComboBox;
    ColFont: TButton;
    RestoreDefaults: TButton;
    LCaption: TLabel;
    TitleCaption: TEdit;
    LAlignment: TLabel;
    LColor: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure ColumnListClick(Sender: TObject);
    procedure AddAllFieldsClick(Sender: TObject);
    procedure ColAlignmentClick(Sender: TObject);
    procedure RestoreDefaultsClick(Sender: TObject);
    procedure ColColorClick(Sender: TObject);
    procedure ColFontClick(Sender: TObject);
    procedure ColColorExit(Sender: TObject);
    procedure TitleCaptionExit(Sender: TObject);
    procedure DeleteAllClick(Sender: TObject);
    procedure DeleteButtonClick(Sender: TObject);
    procedure NewButtonClick(Sender: TObject);
    procedure Newcolumn1Click(Sender: TObject);
    procedure Deletecolumn1Click(Sender: TObject);
    procedure Addallfields1Click(Sender: TObject);
    procedure Deleteallcolumns1Click(Sender: TObject);
    procedure ColumnListDragOver(Sender, Source: TObject; X, Y: Integer;
      State: TDragState; var Accept: Boolean);
    procedure ColumnListDragDrop(Sender, Source: TObject; X, Y: Integer);
  private
    PanelLayout : TAutoPanelLayout;
    ActiveField : TAutoPanelField;

    procedure UpdateColumns;
  public

  end;


function  ShowAutoPanelFieldsEditor(APanelLayout : TAutoPanelLayout) : Boolean;

implementation
uses autostrs, audbstrs;
{$R *.DFM}

function  ShowAutoPanelFieldsEditor(APanelLayout : TAutoPanelLayout) : Boolean;
Var
  AForm : TAutoPanelFieldsEditor;
  i : Integer;
begin
  AForm := TAutoPanelFieldsEditor.Create(Nil);
  with AForm do begin
    Caption := LoadStr(ACDB_PANELFIELDEDITORCAPTION) + APanelLayout.Owner.Name;
    PanelLayout := TAutoPanelLayout.Create(AForm);
    PanelLayout.Assign(APanelLayout);
    ActiveField := Nil;
    if(PanelLayout.DataSet <> Nil) then
      for i := 0 to PanelLayout.DataSet.FieldCount - 1 do
        ColFieldName.Items.Add(PanelLayout.DataSet.Fields[i].FieldName);
    UpdateColumns;        
    ShowModal;
  end;
  if(AForm.ModalResult = mrOk) then begin
    Result := True;
    AForm.ColumnList.ItemIndex := -1;
    AForm.ColumnListClick(Nil);
    APanelLayout.Assign(AForm.PanelLayout);
  end else Result := False;

  AForm.PanelLayout.Free;
  AForm.Free;
end;


procedure TAutoPanelFieldsEditor.UpdateColumns;
Var
  i : Integer;
begin
  ColumnList.Clear;
  for i := 0 to PanelLayout.Fields.Count - 1 do
    if(PanelLayout.Fields[i].Customized) then
      ColumnList.Items.AddObject(PanelLayout.Fields[i].Caption, PanelLayout.Fields[i]);
  ColumnListClick(Nil);          
end;

procedure TAutoPanelFieldsEditor.FormCreate(Sender: TObject);
type
  TGetStrFunc = function(const Value: string): Integer of object;
Var
  Values: TStringList;
  AddValue: TGetStrFunc;
  i : Integer;
begin
  Values := TStringList.Create;
  try
    AddValue := Values.Add;
    GetColorValues(TGetStrProc(AddValue));
    for i := 0 to Values.Count - 1 do
      ColColor.Items.Add(Values[i]);
  finally
    Values.Free;
  end;
  BOK.Caption := LoadStr(ACB_OK);
  BCancel.Caption := LoadStr(ACB_CANCEL);
  BHelp.Caption := LoadStr(ACB_HELP);
  NewButton.Caption := LoadStr(ACB_ADD);
  DeleteButton.Caption := LoadStr(ACB_DELETE);
  AddAllFields.Caption := LoadStr(ACDB_ADDALLFIELDS);
  DeleteAll.Caption := LoadStr(ACDB_DELETEALLFIELDS);
  ColFont.Caption := LoadStr(ACDB_FONTEX);
  RestoreDefaults.Caption := LoadStr(ACDB_RESTORESEFAULTS);
  GB.Caption := LoadStr(ACDB_FIELDS);
  LAlignment.Caption := LoadStr(ACDB_ALIGNMENT);
  LCaption.Caption := LoadStr(ACDB_CAPTION);
  LColor.Caption := LoadStr(ACDB_COLOR);
  LFieldName.Caption := LoadStr(ACDB_FIELDNAME);
  ts1.Caption := LoadStr(ACDB_FIELDPROPERTIES);
end;

procedure TAutoPanelFieldsEditor.ColumnListClick(Sender: TObject);

  procedure SetEnabled(AControl : TWinControl; AEnabled : Boolean);
  Var
    i : Integer;
  begin
    for i := 0 to AControl.ControlCount - 1 do begin
      AControl.Controls[i].Enabled := AEnabled;
      if Not AEnabled then begin
        if (AControl.Controls[i] is TComboBox) then begin
          TComboBox(AControl.Controls[i]).ItemIndex := -1;
          TComboBox(AControl.Controls[i]).Font.Style := [];
        end;
        if (AControl.Controls[i] is TButton) then
          TButton(AControl.Controls[i]).Font.Style := [];
      end;
    end;
  end;

begin
  if(ColumnList.ItemIndex = -1) And (ColumnList.Items.Count > 0) then
    ColumnList.ItemIndex := 0;
  SetEnabled(ts1, ColumnList.ItemIndex > -1);

  if (ActiveField <> Nil) And (Sender <> RestoreDefaults) then begin
    ActiveField.Alignment := TAlignment(ColAlignment.ItemIndex);
    ActiveField.Color := StringToColor(ColColor.Text);
    ActiveField.FieldName := ColFieldName.Text;
    ActiveField.Caption := TitleCaption.Text;
  end;

  if(ColumnList.ItemIndex > -1)
  and (ColumnList.ItemIndex < ColumnList.Items.Count) then begin
    ActiveField := TAutoPanelField(ColumnList.Items.Objects[ColumnList.ItemIndex]);
    ColAlignment.ItemIndex := Integer(ActiveField.Alignment);
    ColAlignmentClick(Sender);
    ColColor.Text := ColorToString(ActiveField.Color);
    ColColorClick(Sender);
    ColFieldName.Text := ActiveField.FieldName;
    if(ActiveField.IsFontStored) then
      ColFont.Font.Style := [fsBold]
    else ColFont.Font.Style := [];
    TitleCaption.Text := ActiveField.Caption;
  end else begin
    ActiveField := Nil;
    TitleCaption.Text := '';
  end;
  ts1.Enabled := ActiveField <> nil;
end;

procedure TAutoPanelFieldsEditor.AddAllFieldsClick(Sender: TObject);
Var
  i : Integer;
  AField : TAutoPanelField;
begin
  if(PanelLayout.DataSet <> Nil) then begin
    PanelLayout.Fields.Clear;
    for i := 0 to PanelLayout.DataSet.FieldCount - 1 do begin
      AField := PanelLayout.Fields.Add;
      AField.Field := PanelLayout.DataSet.Fields[i];
    end;
    UpdateColumns;
  end;
end;

procedure TAutoPanelFieldsEditor.ColAlignmentClick(Sender: TObject);
begin
  if(ActiveField.DefaultAlignment = TAlignment(ColAlignment.ItemIndex)) then
    ColAlignment.Font.Style := []
  else ColAlignment.Font.Style := [fsBold];
end;

procedure TAutoPanelFieldsEditor.RestoreDefaultsClick(Sender: TObject);
begin
  ActiveField.RestoreDefaults;
  ColumnListClick(Sender);
end;

procedure TAutoPanelFieldsEditor.ColColorClick(Sender: TObject);
begin
  if(ColorToString(ActiveField.DefaultColor) = ColColor.Text) then
    ColColor.Font.Style := []
  else ColColor.Font.Style := [fsBold];
end;

procedure TAutoPanelFieldsEditor.ColFontClick(Sender: TObject);
begin
  FontDialog.Font.Assign(ActiveField.Font);
  if(FontDialog.Execute) then
    ActiveField.Font := FontDialog.Font;
  if Not (pfvFont in ActiveField.AssignedValues) then
    ColFont.Font.Style := []
  else ColFont.Font.Style := [fsBold];
end;

procedure TAutoPanelFieldsEditor.ColColorExit(Sender: TObject);
Var
  dummy : LongInt;
begin
  if Not IdentToColor(ColColor.Text, dummy) then
    ColColor.Text := ColorToString(ActiveField.Color);
end;

procedure TAutoPanelFieldsEditor.TitleCaptionExit(Sender: TObject);
Var
  OldIndex : Integer;
begin
  OldIndex := ColumnList.ItemIndex;
  ColumnList.Items[OldIndex] := TitleCaption.Text;
  ColumnList.ItemIndex := OldIndex;
end;

procedure TAutoPanelFieldsEditor.DeleteAllClick(Sender: TObject);
begin
  ActiveField := Nil;
  PanelLayout.Fields.Clear;
  UpdateColumns;
end;

procedure TAutoPanelFieldsEditor.DeleteButtonClick(Sender: TObject);
Var
  OldItemIndex : Integer;
begin
  if(ActiveField <> Nil) then begin
    ActiveField.Free;
    ActiveField := Nil;
    OldItemIndex := ColumnList.ItemIndex;
    ColumnList.Items.Delete(OldItemIndex);
    if(OldItemIndex >= ColumnList.Items.Count) then
      Dec(OldItemIndex);
    ColumnList.ItemIndex := OldItemIndex;
    ColumnListClick(Sender);
  end;
end;

procedure TAutoPanelFieldsEditor.NewButtonClick(Sender: TObject);
Var
  AField : TAutoPanelField;
begin
  AField := PanelLayout.Fields.Add;
  ColumnList.Items.AddObject(AField.Caption, AField);
  ColumnList.ItemIndex := ColumnList.Items.Count - 1;
  ColumnListClick(Sender);
end;

procedure TAutoPanelFieldsEditor.Newcolumn1Click(Sender: TObject);
begin
  NewButtonClick(Sender);
end;

procedure TAutoPanelFieldsEditor.Deletecolumn1Click(Sender: TObject);
begin
  DeleteButtonClick(Sender);
end;

procedure TAutoPanelFieldsEditor.Addallfields1Click(Sender: TObject);
begin
  AddAllFieldsClick(Sender);
end;

procedure TAutoPanelFieldsEditor.Deleteallcolumns1Click(Sender: TObject);
begin
  DeleteAllClick(Sender);
end;

procedure TAutoPanelFieldsEditor.ColumnListDragOver(Sender, Source: TObject;
  X, Y: Integer; State: TDragState; var Accept: Boolean);
begin
  Accept := True; 
end;

procedure TAutoPanelFieldsEditor.ColumnListDragDrop(Sender, Source: TObject;
  X, Y: Integer);
Var
  AIndex1, AIndex2 : Integer;
begin
  AIndex1 := ColumnList.ItemAtPos(Point(X, Y), True);
  if(AIndex1 > -1) then begin
    AIndex2 := ColumnList.ItemIndex;
    ColumnList.Items.Move(AIndex2, AIndex1);
    Panellayout.Fields[AIndex2].Index := AIndex1;
    ColumnList.ItemIndex := AIndex1;
    ColumnListClick(Sender);
  end;
end;

end.