afformed.pas

来自「delphi编程控件」· PAS 代码 · 共 300 行

unit afformed;
(*
 COPYRIGHT (c) RSD software 1997 - 98
 All Rights Reserved.
*)

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Menus, StdCtrls, ComCtrls, afforms, DBTables, DB;

type
  TFAutoFieldFieldsEditor = class(TForm)
    BHelp: TButton;
    BCancel: TButton;
    BOk: TButton;
    GB: TGroupBox;
    ColumnList: TListBox;
    NewButton: TButton;
    DeleteButton: TButton;
    AddAllFields: TButton;
    DeleteAll: TButton;
    FontDialog: TFontDialog;
    PM: TPopupMenu;
    Newcolumn1: TMenuItem;
    Deletecolumn1: TMenuItem;
    Addallfields1: TMenuItem;
    Deleteallcolumns1: TMenuItem;
    ts1: TGroupBox;
    ColAlignment: TComboBox;
    LFieldName: TLabel;
    ColFieldName: TComboBox;
    ColFont: TButton;
    RestoreDefaults: TButton;
    LCaption: TLabel;
    TitleCaption: TEdit;
    LAlignment: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure ColumnListClick(Sender: TObject);
    procedure AddAllFieldsClick(Sender: TObject);
    procedure ColAlignmentClick(Sender: TObject);
    procedure RestoreDefaultsClick(Sender: TObject);
    procedure ColFontClick(Sender: TObject);
    procedure TitleCaptionExit(Sender: TObject);
    procedure DeleteAllClick(Sender: TObject);
    procedure DeleteButtonClick(Sender: TObject);
    procedure NewButtonClick(Sender: TObject);
    procedure Newcolumn1Click(Sender: TObject);
    procedure Deletecolumn1Click(Sender: TObject);
    procedure Addallfields1Click(Sender: TObject);
    procedure Deleteallcolumns1Click(Sender: TObject);
    procedure ColumnListDragOver(Sender, Source: TObject; X, Y: Integer;
      State: TDragState; var Accept: Boolean);
    procedure ColumnListDragDrop(Sender, Source: TObject; X, Y: Integer);
  private
    FilterForm : TCustomAutoFilterForm;
    ActiveField : TAutoFilterField;

    procedure UpdateColumns;
  public

  end;


function  ShowAutoFilterFieldsEditor(AFilterForm : TCustomAutoFilterForm) : Boolean;

implementation
uses autostrs, audbstrs;
{$R *.DFM}

function  ShowAutoFilterFieldsEditor(AFilterForm : TCustomAutoFilterForm) : Boolean;
Var
  AForm : TFAutoFieldFieldsEditor;
  i : Integer;
begin
  AForm := TFAutoFieldFieldsEditor.Create(Nil);
  with AForm do begin
    Caption := LoadStr(ACDB_PANELFIELDEDITORCAPTION) + AFilterForm.Name;
    FilterForm := TCustomAutoFilterForm.Create(Nil);
    FilterForm.FilterFields.Assign(AFilterForm.FilterFields);
    FilterForm.DataSet := AFilterForm.DataSet;
    ActiveField := Nil;
    if(FilterForm.DataSet <> Nil) then
      for i := 0 to FilterForm.DataSet.FieldCount - 1 do
        if Not(FilterForm.Dataset.Fields[i] is TBlobField) then
          ColFieldName.Items.Add(FilterForm.DataSet.Fields[i].FieldName);
    UpdateColumns;
    ShowModal;
  end;
  if(AForm.ModalResult = mrOk) then begin
    Result := True;
    AForm.ColumnList.ItemIndex := -1;
    AForm.ColumnListClick(Nil);
    AFilterForm.FilterFields.Assign(AForm.FilterForm.FilterFields);
  end else Result := False;

  AForm.FilterForm.Free;
  AForm.Free;
end;


procedure TFAutoFieldFieldsEditor.UpdateColumns;
Var
  i : Integer;
begin
  ColumnList.Clear;
  for i := 0 to FilterForm.FilterFields.Count - 1 do
    ColumnList.Items.AddObject(FilterForm.FilterFields[i].Caption,
        FilterForm.FilterFields[i]);
  ColumnListClick(Nil);          
end;

procedure TFAutoFieldFieldsEditor.FormCreate(Sender: TObject);
begin
  BOK.Caption := LoadStr(ACB_OK);
  BCancel.Caption := LoadStr(ACB_CANCEL);
  BHelp.Caption := LoadStr(ACB_HELP);
  NewButton.Caption := LoadStr(ACB_ADD);
  DeleteButton.Caption := LoadStr(ACB_DELETE);
  AddAllFields.Caption := LoadStr(ACDB_ADDALLFIELDS);
  DeleteAll.Caption := LoadStr(ACDB_DELETEALLFIELDS);
  ColFont.Caption := LoadStr(ACDB_FONTEX);
  RestoreDefaults.Caption := LoadStr(ACDB_RESTORESEFAULTS);
  GB.Caption := LoadStr(ACDB_FIELDS);
  LAlignment.Caption := LoadStr(ACDB_ALIGNMENT);
  LCaption.Caption := LoadStr(ACDB_CAPTION);
  LFieldName.Caption := LoadStr(ACDB_FIELDNAME);
  ts1.Caption := LoadStr(ACDB_FIELDPROPERTIES);
end;

procedure TFAutoFieldFieldsEditor.ColumnListClick(Sender: TObject);

  procedure SetEnabled(AControl : TWinControl; AEnabled : Boolean);
  Var
    i : Integer;
  begin
    for i := 0 to AControl.ControlCount - 1 do begin
      AControl.Controls[i].Enabled := AEnabled;
      if Not AEnabled then begin
        if (AControl.Controls[i] is TComboBox) then begin
          TComboBox(AControl.Controls[i]).ItemIndex := -1;
          TComboBox(AControl.Controls[i]).Font.Style := [];
        end;
        if (AControl.Controls[i] is TButton) then
          TButton(AControl.Controls[i]).Font.Style := [];
      end;
    end;
  end;

begin
  if(ColumnList.ItemIndex = -1) And (ColumnList.Items.Count > 0) then
    ColumnList.ItemIndex := 0;
  SetEnabled(ts1, ColumnList.ItemIndex > -1);

  if (ActiveField <> Nil) And (Sender <> RestoreDefaults) then begin
    ActiveField.Alignment := TAlignment(ColAlignment.ItemIndex);
    ActiveField.FieldName := ColFieldName.Text;
    ActiveField.Caption := TitleCaption.Text;
  end;

  if(ColumnList.ItemIndex > -1) and (ColumnList.Items.Count > 0) then begin
    ActiveField := TAutoFilterField(ColumnList.Items.Objects[ColumnList.ItemIndex]);
    ColAlignment.ItemIndex := Integer(ActiveField.Alignment);
    ColAlignmentClick(Sender);
    ColFieldName.Text := ActiveField.FieldName;
    if(ActiveField.Font = ActiveField.DefaultFont) then
      ColFont.Font.Style := []
    else ColFont.Font.Style := [fsBold];
    TitleCaption.Text := ActiveField.Caption;
  end else begin
    ActiveField := Nil;
    TitleCaption.Text := '';
  end;
end;

procedure TFAutoFieldFieldsEditor.AddAllFieldsClick(Sender: TObject);
Var
  i : Integer;
  AField : TAutoFilterField;
begin
  if(FilterForm.DataSet <> Nil) then begin
    FilterForm.FilterFields.Clear;
    for i := 0 to FilterForm.DataSet.FieldCount - 1 do
      if Not(FilterForm.Dataset.Fields[i] is TBlobField) then begin
        AField := FilterForm.FilterFields.Add;
        AField.Field := FilterForm.DataSet.Fields[i];
      end;
    UpdateColumns;
  end;
end;

procedure TFAutoFieldFieldsEditor.ColAlignmentClick(Sender: TObject);
begin
  if(ActiveField.DefaultAlignment = TAlignment(ColAlignment.ItemIndex)) then
    ColAlignment.Font.Style := []
  else ColAlignment.Font.Style := [fsBold];
end;

procedure TFAutoFieldFieldsEditor.RestoreDefaultsClick(Sender: TObject);
begin
  ActiveField.RestoreDefaults;
  ColumnListClick(Sender);
end;

procedure TFAutoFieldFieldsEditor.ColFontClick(Sender: TObject);
begin
  FontDialog.Font.Assign(ActiveField.Font);
  if(FontDialog.Execute) then
    ActiveField.Font := FontDialog.Font;
  if Not (ffvFont in ActiveField.AssignedValues) then
    ColFont.Font.Style := []
  else ColFont.Font.Style := [fsBold];
end;

procedure TFAutoFieldFieldsEditor.TitleCaptionExit(Sender: TObject);
Var
  OldIndex : Integer;
begin
  OldIndex := ColumnList.ItemIndex;
  ColumnList.Items[OldIndex] := TitleCaption.Text;
  ColumnList.ItemIndex := OldIndex;
end;

procedure TFAutoFieldFieldsEditor.DeleteAllClick(Sender: TObject);
begin
  ActiveField := Nil;
  FilterForm.FilterFields.Clear;
  UpdateColumns;
end;

procedure TFAutoFieldFieldsEditor.DeleteButtonClick(Sender: TObject);
Var
  OldItemIndex : Integer;
begin
  if(ActiveField <> Nil) then begin
    ActiveField.Free;
    ActiveField := Nil;
    OldItemIndex := ColumnList.ItemIndex;
    ColumnList.Items.Delete(OldItemIndex);
    if(OldItemIndex >= ColumnList.Items.Count) then
      Dec(OldItemIndex);
    ColumnList.ItemIndex := OldItemIndex;
    ColumnListClick(Sender);
  end;
end;

procedure TFAutoFieldFieldsEditor.NewButtonClick(Sender: TObject);
Var
  AField : TAutoFilterField;
begin
  AField := FilterForm.FilterFields.Add;
  ColumnList.Items.AddObject(AField.Caption, AField);
  ColumnList.ItemIndex := ColumnList.Items.Count - 1;
  ColumnListClick(Sender);
end;

procedure TFAutoFieldFieldsEditor.Newcolumn1Click(Sender: TObject);
begin
  NewButtonClick(Sender);
end;

procedure TFAutoFieldFieldsEditor.Deletecolumn1Click(Sender: TObject);
begin
  DeleteButtonClick(Sender);
end;

procedure TFAutoFieldFieldsEditor.Addallfields1Click(Sender: TObject);
begin
  AddAllFieldsClick(Sender);
end;

procedure TFAutoFieldFieldsEditor.Deleteallcolumns1Click(Sender: TObject);
begin
  DeleteAllClick(Sender);
end;

procedure TFAutoFieldFieldsEditor.ColumnListDragOver(Sender, Source: TObject;
  X, Y: Integer; State: TDragState; var Accept: Boolean);
begin
  Accept := True; 
end;

procedure TFAutoFieldFieldsEditor.ColumnListDragDrop(Sender, Source: TObject;
  X, Y: Integer);
Var
  AIndex1, AIndex2 : Integer;
begin
  AIndex1 := ColumnList.ItemAtPos(Point(X, Y), True);
  if(AIndex1 > -1) then begin
    AIndex2 := ColumnList.ItemIndex;
    ColumnList.Items.Move(AIndex2, AIndex1);
    FilterForm.FilterFields[AIndex2].Index := AIndex1;
    ColumnList.ItemIndex := AIndex1;
    ColumnListClick(Sender);
  end;
end;

end.