📄 admin_article.asp

📁 WEB后台:/Admin_Login.asp WAP后台:/Admin_WapLogin.asp 用户名：admin 密码:admin 在conn.asp文件修改数据库
💻 ASP
字号:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<!--#include file="Conn.asp"-->
<%
If Session(SiteSN&"_Admin_Login")<>AdminName&"_"&AdminPass Then
   Response.redirect "Admin_Login.asp"
   Response.End
End If

dim Action
Action=Request.QueryString("Action")
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN" 
    "http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=UTF-8">
<link href="style.css" rel="stylesheet" type="text/css">
<title>管理网站信息_<%=WebName & ChannelName%></title>
<script language="javascript">
function EditFile(ArticleID,filename)
		{
			var ReturnValue='';
			ReturnValue=prompt('修改的名称：',filename);
			if ((ReturnValue!='') && (ReturnValue!=null)) window.location.href='Admin_Article.asp?Action=FileReName&ArticleID='+ArticleID+'&ArticleName='+ReturnValue;
				else if(ReturnValue!=null){alert('请填写要更名的名称');}
		}
</script>
</head>
<body>
<div class="main_title1">
<a href="Admin_Manage.asp">管理首页</a> | <a href="Admin_Article.asp?Action=GoSave">增加定义页面</a> | <a href="Admin_Article.asp">管理定义页面</a> | <a href="admin_login.asp?action=exit">退出管理</a>
</div>

<div class="mainbar">
<%
select case Action
case "FileReName"'重命名
    call FileReName
case "Del"
    call Del
case "TemplateSave"
    call TemplateSave
case "GoSave"
    call GoSave
case else
	call main
end select
%></div>
<%

sub main


dim MaxPageSize:MaxPageSize=20 '每页显示的记录数


'分页信息
dim PageNo
PageNo=Request.QueryString("PageNo")
if PageNo="" or not Isnumeric(PageNo) then
PageNo=1
else
PageNo=int(PageNo)
end if

'普通sql语句
sql="select * from Article order by inout desc"

%> 
<div style="text-align:center;">
  <div class="cutpage">      
<%Wap.showPageInfo "Article","ArticleID","",PageNo,MaxPageSize,""%>
</div>
</div>
<%

set rs=server.createobject("adodb.recordset")
rs.open sql,Conn,1,1

if not rs.eof then
	rs.PageSize = MaxPageSize
	rs.AbsolutePage = PageNo 
	dim i
	i=0   
%>
<table width="746" border="1" align="center" cellpadding="3" cellspacing="0" bordercolorlight="#000000" bordercolordark="#FFFFFF">
  <tr align="center" class="main_title1"> 
    <td width="30">编号</td>
    <td width="355">调用代码</td>
    <td width="129">页面名称</td>
    <td width="70">修改时间间</td>
    <td width="120">操作管理</td>
  </tr>
 
  
  <%Do While Not rs.EOF and i<MaxPageSize%>
  <tr align="center"> 
    <td><%=rs("ArticleID")%></td>
    
    <td>
    <%
	If Rs("inout")=0 Then
      Response.write "<textarea name=""textarea"" style=""width:95%;height:15px;""><a href=""Wap_Article.asp?id="&rs("ArticleID")&""">"&Trim(rs("ArticleName"))&"</a></textarea>"
    Else
       Response.write Trim(rs("ArticleName"))
    End If
	%>
    </td>
    
    <td>
    <%
    If Rs("inout")=0 Then
       Response.write Trim(rs("ArticleName"))
    Else
       Response.write "系统数据"
    End If
	%>
    </td>
    <td><%=rs("ArticleDate")%></td>
    <td>
    <%
    Response.write "<a href=""Admin_Article.asp?Action=GoSave&ArticleID="&rs("ArticleID")&""">页面编辑</a>"
	If Rs("inout")=0 Then
       Response.write "| <a href=""javascript:EditFile('"&rs("ArticleID")&"','"&rs("ArticleName")&"')"">重命名</a>"
       Response.write "| <a href=""Admin_Article.asp?Action=Del&ArticleID="&rs("ArticleID")&""" onClick=""return(confirm('此操作不可逆，确定删除吗？'))"">删除</a>"
    End If
    %>    </td>
  </tr>
  <tr> 
    <td height="1" colspan="7" bgcolor="#8cc3de"></td>
  </tr>
  <%  
i=i+1  
rs.MoveNext  
Loop  
else
%>
  <tr> 
    <td height="80" colspan="7" align="center"><B>没有WAP定义页面</B></td>
  </tr>
  <%
end if  
rs.close
set rs=nothing

%>
</table>
<%
end sub

'导入模板
Sub GoSave()
    ArticleID=Cstr(Request("ArticleID"))
	If ArticleID="" Then ArticleID=0
	Set Rs = Conn.Execute("select * from Article where ArticleID="&ArticleID)
		If not (Rs.EOF And Rs.BOF) Then
		   ArticleID=rs("ArticleID")
		   ArticleName=Wap.HTMLCode(rs("ArticleName"))
		   ArticleContent=Wap.HTMLCode(rs("Content"))
		   strtitle="修改WAP定义页面"
		   submit1="修改页面"
		Else
		   ArticleName="请在此处输入WAP页面名称"
		   ArticleContent="请在此处输入模板代码"
		   strtitle="增加WAP定义页面"
		   submit1="增加页面"
		End if
		
	%> 
    
    <p align="center"><%=strtitle%></p>
    <form method="post" Action="?Action=TemplateSave&ArticleID=<% =ArticleID %>">
       <table width="68%" border="0" align="center" cellpadding="3" cellspacing="1" bgcolor="#000000">



<tr class="tr2"> 
            <td width="17%" align="center">页面名称：</td>
      <td width="83%" colspan="5"><input name="ArticleName" type="text" size="40"  value="<% =ArticleName %>" ></td>
         </tr>

                    <tr class="tr2"> 
            <td colspan="6" align="center">
            <textarea name="ArticleContent" rows="15" cols="90" class="text"><% =ArticleContent %>
            </textarea>
            </td>
            </tr>
          <tr class="tr2"> 
            <td colspan="6" align="center" class="td"> <input name="submit1" type="submit" value="<%=submit1%>">
          &nbsp;&nbsp;<input type="reset" value=" 重新输入 "></td>
          </tr>
  </table>
      </form>
<%
end sub

'删除
Sub Del()
    ArticleID=Cstr(Request("ArticleID"))
	Conn.execute("Delete from Article where ArticleID="&ArticleID&"")
	Response.write "<script>window.alert('删除成功');window.location='Admin_Article.asp';</script>"
End Sub

'重命名
Sub FileReName()
    ArticleID=Cstr(Request("ArticleID"))
	ArticleName = Request("ArticleName")
	Conn.execute("Update Article set ArticleName='"&ArticleName&"' where ArticleID="&ArticleID&"")
	Response.write "<script>window.alert('重命名成功');window.location='Admin_Article.asp';</script>"
End Sub


Sub TemplateSave()
    ArticleID=Cstr(Request("ArticleID"))
	ArticleName=Wap.HTMLEncode(Request.form("ArticleName"))
	ArticleDate=Date()
    Content=Wap.HTMLEncode(Request.form("ArticleContent"))
    If ArticleName="" then
        Response.write "<script>window.alert('标题没有填写..');window.location='javascript:history.go(-1)';</script>"
		Response.End
	End if

	If ArticleID>0 then
	   set rs=server.createobject("adodb.recordset")
	  sql="select * from Article where ArticleID="&ArticleID
	   rs.open sql,Conn,1,3
	   rs("ArticleName")=ArticleName
	   rs("Content")=Content
	   rs("ArticleDate")=ArticleDate
	   'rs("inout")=0
	   rs.update
	   rs.close:set rs=nothing
	   Response.write "<div class=""cutpage"">"
	   Response.write "<p>文章信息已修改完成</p>"
	   Response.write "<p><a href=""Admin_Article.asp"">返回上一页</a> <a href=""admin_manage.asp"">返回管理首页</a></p>"
	   Response.write "</div>"
	Else
	set rs=server.createobject("adodb.recordset")
      rs.open "select * from Article where ArticleName='" & ArticleName & "'",Conn,1,3
  	   rs.addnew
	   rs("ArticleName")=ArticleName
	   rs("Content")=Content
	   rs("ArticleDate")=ArticleDate
	   'rs("inout")=0
	   rs.update
	   Response.write "<div class=""cutpage"">"
	   Response.write "<p>文章信息已添加完成</p>"
	   Response.write "<p><a href=""Admin_Article.asp"">返回上一页</a> <a href=""admin_manage.asp"">返回管理首页</a></p>"
	   Response.write "</div>"
	   rs.close:set rs=nothing
	End if

End Sub
%>


<!--#include file="under.asp"-->
<%set Wap=nothing%>
💿 文件大小 135 K
👤 上传用户 wangcong200500
📂 所属分类其他
🏷️ 相关标签

#asp #admin #Admin_WapLogin #Admin_Login
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -