form1.frm

VB连接SQL实例,对初学者很有帮助,帮助大大滴有

VERSION 5.00
Begin VB.Form Form1 
   Caption         =   "使用EOF和BOF属性"
   ClientHeight    =   3090
   ClientLeft      =   60
   ClientTop       =   450
   ClientWidth     =   5460
   LinkTopic       =   "Form1"
   ScaleHeight     =   3090
   ScaleWidth      =   5460
   StartUpPosition =   2  '屏幕中心
   Begin VB.CommandButton Command1 
      Caption         =   "使用EOF和BOF属性"
      Height          =   615
      Left            =   1560
      TabIndex        =   0
      Top             =   960
      Width           =   2415
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Public Sub BOFX()
   '定义有关ADO对象和临时变量
   Dim rstPublishers As ADODB.Recordset
   Dim strCnn As String
   Dim strMessage As String
   Dim intCommand As Integer
   Dim varBookmark As Variant
   '使用来自出版商表的数据打开记录集
   strCnn = "Provider=sqloledb; Data Source=mynetserver;Initial Catalog=pubs;User Id=sa;Password=12345678;"
   Set rstPublishers = New ADODB.Recordset
   '定义游标类型
rstPublishers.CursorType = adOpenStatic
   '使用客户机游标启用 AbsolutePosition 属性
   rstPublishers.CursorLocation = adUseClient
   rstPublishers.Open "SELECT pub_id, pub_name FROM publishers " & _
      "ORDER BY pub_name", strCnn, , , adCmdText
   '移动到第一条记录
   rstPublishers.MoveFirst
   Do While True
      '显示关于当前记录的信息并让用户选择
      strMessage = "出版商: " & rstPublishers!pub_name & _
      vbCr & "(当前记录号：" & rstPublishers.AbsolutePosition & _
      " 总记录数： " & rstPublishers.RecordCount & ")" & vbCr & vbCr & _
         "选择命令:" & vbCr & _
         "[1 - 下一条 / 2 - 上一条 /" & vbCr & _
         "3 - 设置书签 / 4 - 跳转到指定书签]"
      '获取输入的命令
      intCommand = Val(InputBox(strMessage))
      '根据不同的命令执行不同的操作
      Select Case intCommand
         '向前或向后移动，捕获 BOF 或 EOF
         Case 1
            rstPublishers.MoveNext
            If rstPublishers.EOF Then
               MsgBox "移动超越最后记录." & _
                  vbCr & "再次尝试."
               rstPublishers.MoveLast
            End If
         Case 2
            rstPublishers.MovePrevious
            If rstPublishers.BOF Then
               MsgBox "移动超越第一条记录." & _
                  vbCr & "再次尝试."
               rstPublishers.MoveFirst
            End If
         '保存当前记录的书签
         Case 3
            varBookmark = rstPublishers.Bookmark
         '转到由存储的书签所指示的记录
         Case 4
            If IsEmpty(varBookmark) Then
               MsgBox "没有设置书签!"
            Else
               rstPublishers.Bookmark = varBookmark
            End If
         Case Else
            Exit Do
      End Select
   Loop
   rstPublishers.Close
End Sub


Private Sub Command1_Click()
  Call BOFX
End Sub