gaecnrga.s54

TI公司DSP/tms320c55x/tms320c54x系列的声学回声消除代码

*-------------------------------------------------------------------------*
*                                                                         *
*   THIS IS AN UNPUBLISHED WORK CONTAINING CONFIDENTIAL AND PROPRIETARY   *
*   INFORMATION.  IF PUBLICATION OCCURS, THE FOLLOWING NOTICE APPLIES:    *
*      "COPYRIGHT 2003 MICHAEL TSIROULNIKOV, ALL RIGHTS RESERVED"         *
*                                                                         *
*-------------------------------------------------------------------------*/
	.mmregs
	.include "gaeci.h54"
	.sect ".ftext2"

	.ref	_gaec_utl_en2log
_EN_CORR            	.set (-3*GAEC_1DB - GAEC_1DB/2)

;-------------------------------------------------------------------------
	.global _gaec_nrg_rcv
;-------------------------------------------------------------------------
_gaec_nrg_rcv
; GAEC_tDb *pDb,
; GAEC_tSc *pSc
;
	stlm	a, ar2
	ssbx 	sxm
	nop
	mvdk	*sp(1), ar3
;	
; set ptrs
; ar3 = pSc->asRcvEn
; ar4 =	psRcvI
; ar5 = psRcvQ
;
	mvdk	*ar2(#GAEC_tDb.psRcv), ar4
	mar 	*+ar4(#GAEC_ADF_SZ-1)
	mvmm	ar4, ar5
	mar 	*+ar5(#GAEC_RCV_SZ*GAEC_BANDS)
	mar		*+ar3(#GAEC_tSc.asRoutEn)
;
; band 0, BANDS	
	rptz	a, #GAEC_BLKS-1
		squra 	*ar5+, a
	call 	_gaec_utl_en2log
	stl 	a, *ar3(#GAEC_BANDS)

	rptz	a, #GAEC_BLKS-1
		squra 	*ar4+, a
	call 	_gaec_utl_en2log
	stl 	a, *ar3+
	
	stm		#(GAEC_BANDS-1)-1, brc
	rptb	E10-1
		mar 	*+ar4(#GAEC_RCV_SZ-GAEC_BLKS)
		mar 	*+ar5(#GAEC_RCV_SZ-GAEC_BLKS)
		rptz	a, #GAEC_BLKS-1
			squra	*ar4+, a
		rpt 	#GAEC_BLKS-1
			squra	*ar5+, a
		call 	_gaec_utl_en2log
		stl 	a, *ar3+
E10	
	ret		
		
;-------------------------------------------------------------------------
	.global _gaec_nrg_blk
;-------------------------------------------------------------------------
_gaec_nrg_blk
; S16 *psFrom	= a
; S16 *psTo		= sp(1)
;
	stlm	a, ar4
	ssbx 	sxm
	nop
	mvdk	*sp(1), ar3

	mvmm	ar4, ar5
	mar 	*+ar5(#GAEC_BLKS*GAEC_BANDS)
;
; band 0, BANDS	
	rptz	a, #GAEC_BLKS-1
		squra 	*ar5+, a
	call 	_gaec_utl_en2log
	stl 	a, *ar3(#GAEC_BANDS)

	rptz	a, #GAEC_BLKS-1
		squra 	*ar4+, a
	call 	_gaec_utl_en2log
	stl 	a, *ar3+
; bands 1...BANDS-1	
	stm		#(GAEC_BANDS-1)-1, brc
	rptb	E20-1
		rptz	a, #GAEC_BLKS-1
			squra	*ar4+, a
		rpt 	#GAEC_BLKS-1
			squra	*ar5+, a
		call 	_gaec_utl_en2log
		stl 	a, *ar3+
E20	
	ret		
		
	
;-------------------------------------------------------------------------
	.global _gaec_nrg_err
;-------------------------------------------------------------------------
_gaec_nrg_err
; S16 *psFrom	= a
; S16 *psTo		= sp(1)
;
	stlm	a, ar4
	ssbx 	sxm
	nop
	mvdk	*sp(1), ar3
;	
	mvmm	ar4, ar5
	mar 	*+ar5(#GAEC_ERR_SZ*GAEC_BANDS)
;
; band 0, BANDS	
	rptz	a, #GAEC_ERR_SZ-1
		squra 	*ar5+, a
	call 	_gaec_utl_en2log
	add 	#_EN_CORR, a
	stl 	a, *ar3(#GAEC_BANDS)

	rptz	a, #GAEC_ERR_SZ-1
		squra 	*ar4+, a
	call 	_gaec_utl_en2log
	add 	#_EN_CORR, a
	stl 	a, *ar3+
	
	stm		#(GAEC_BANDS-1)-1, brc
	rptb	E30-1
		rptz	a, #GAEC_ERR_SZ-1
			squra	*ar4+, a
		rpt 	#GAEC_ERR_SZ-1
			squra	*ar5+, a
		call 	_gaec_utl_en2log
		add 	#_EN_CORR, a
		stl 	a, *ar3+
E30	
	ret