startup.s

基于Freescale的MX21处理器的bootloader程序

;************************************************************************
;*  Name: init.s
;*  Description: MC9328MX21 initialize routine
;*  Author: wyf
;*  Date: 2006.07.11
;************************************************************************
;************************************************************************
	PRESERVE8
	AREA    Init, CODE, READONLY
	INCLUDE MX21_defs.s
	ENTRY
    EXPORT  Reset_Handler
Reset_Handler
;**********************************
;* Set SVC and lock IRQ/FIQ       *
;**********************************
	MRS r0,CPSR
	ORR r0,r0,#I_Bit:OR:F_Bit:OR:Mode_SVC
	MSR CPSR_c,r0 
	
;**********************************
;* Disable Cache                  * 
;**********************************
;	MRC p15,0,r0,c1,c0,0
;	LDR r1,=0x00001005 
;	BIC r0,r0,r1 
	LDR r0,=0x00050078 
	MCR p15,0,r0,c1,c0,0 

;**********************************
;* Disable all interrupt          * 
;**********************************
	MOV r0,#0
	LDR r1,=INTENABLEH
	STR r0,[R1]
	LDR r1,=INTENABLEL
	STR r0,[R1]

;**********************************
;* Configure stack                * 
;**********************************
	LDR sp,=0xfffffffc
 
;**********************************
;* Configure SYSTEM CLOCK         *
;* FCLK:266M HCLK:133M            *
;**********************************
	IMPORT Pll_init
	BL Pll_init
;**********************************
;* Configure AHP Priority         *
;**********************************
	LDR r0,=MPR3
	LDR r1,=0x00123056
	STR r1,[r0]

;**********************************
;* Configure SDRAM                *
;* 16Mx16x2 IAM=0 CSD0 CL3        *
;**********************************
	MOV r0, pc
	LDR r1, =0xc8000000
	cmp r0, r1
;	BGT	%f1
	IMPORT Sdram_init
	BLGT Sdram_init
;1
;**********************************
;* Configure EIM                  *
;* CS0 as flash                   *
;* CS1 as Mapped IO               *
;**********************************
	LDR r1,=0x00000A00
	LDR r0,=CS0U
	STR r1,[r0]
	LDR r1,=0x00000E01
	LDR r0,=CS0L
	STR r1,[r0]

	LDR r1,=0x00002000
	LDR r0,=CS1U
	STR r1,[r0]
	LDR r1,=0x11118501
	LDR r0,=CS1L
	STR r1,[r0]

;**********************************
;* Transit Code                   *
;**********************************
    IMPORT TCT_Transit_Code
	BL TCT_Transit_Code
  
;**********************************
;* Now enter the RTOS code        *
;**********************************
	IMPORT INT_Initialize
	B INT_Initialize

    END