drv_display.s

基于Freescale的MX21处理器的bootloader程序

;************************************************************************
;*  Name: drv_disp.s
;*  Description: display driver.s
;*  Author: wyf
;*  Date: 2006.07.17
;************************************************************************
;************************************************************************
	PRESERVE8
	AREA drvdisplay, CODE, READONLY
;	INCLUDE MX21_defs.s

IMAGE_WIDTH   EQU   320
IMAGE_HEIGHT  EQU   240

	ENTRY
;**********************************
;* unsigned int BufIn             *
;* unsigned int BufOut            * 
;**********************************
	EXPORT RGB_320x240_to_240x320
RGB_320x240_to_240x320
	STMFD SP!,{r3-r12,r14}			;save the register of this code using
	LDR r2,=320
	LDR r3,=240
	SUB r14,r3,#1
	MOV r4,#0
	B endloop1
loop1
	MOV r3,r14
loop2
	; 1
	MLA r5,r2,r3,r4
	ADD r5,r0,r5,LSL #1
	LDRH r6,[r5]
	SUB r5,r5,r2,LSL #1
	LDRH r12,[r5]
	; 2
	SUB r5,r5,r2,LSL #1
	LDRH r7,[r5]
	ADD r6,r6,r12,LSL #16
	SUB r5,r5,r2,LSL #1
	LDRH r12,[r5]
	; 3
	SUB r5,r5,r2,LSL #1
	LDRH r8,[r5]
	ADD r7,r7,r12,LSL #16
	SUB r5,r5,r2,LSL #1
	LDRH r12,[r5]
	; 4
	SUB r5,r5,r2,LSL #1
	LDRH r9,[r5]
	ADD r8,r8,r12,LSL #16
	SUB r5,r5,r2,LSL #1
	LDRH r12,[r5]
	; 5
	SUB r5,r5,r2,LSL #1
	LDRH r10,[r5]
	ADD r9,r9,r12,LSL #16
	SUB r5,r5,r2,LSL #1
	LDRH r12,[r5]
	; 6
	SUB r5,r5,r2,LSL #1
	LDRH r11,[r5]
	ADD r10,r10,r12,LSL #16
	SUB r5,r5,r2,LSL #1
	LDRH r12,[r5]
	NOP
	NOP
	ADD r11,r11,r12,LSL #16

	STMIA r1!, {r6-r11}

	SUBS r3,r3,#12
endloop2
	CMP r3,#0
	BGE loop2

	ADD r4,r4,#1
endloop1
	CMP r4,r2
	BCC loop1

goback
	LDMFD SP!,{r3-r12,pc}            ;restore the register

	END