hd6305.ld

HD6305的Tag_IT电子标签的读写例子。

/* STARTUP(crt0.o) */
OUTPUT_ARCH(m68k)
OUTPUT_FORMAT("coff-m68k")
GROUP(-lgcc -lg -lm -lm2002 -lmcard -lconso -lstd mifare530.a iso15693.a cdcl_rc632.a)

MEMORY
{
  ram   : ORIGIN = 0x05040000, LENGTH = 256k
  rom   : ORIGIN = 0x0005000C, LENGTH = 704k
}

/*
MEMORY
{
  rom   : ORIGIN = 0x00004000, LENGTH = 500K
  ram   : ORIGIN = 0x00024000, LENGTH = 300k
}
*/
PROVIDE (__stack = 0);

SECTIONS
{
  .text :
  {
    *(.text)
     . = ALIGN(4);
     etext  =  .;
     __CTOR_LIST__ = .;
     LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
     *(.ctors)
     LONG(0)
     __CTOR_END__ = .;
     __DTOR_LIST__ = .;
     LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
     *(.dtors)
     LONG(0)
     __DTOR_END__ = .;
    _etext = ALIGN(4);
  } > rom


  .data :
  AT(_etext)
  {
    _data = .;
    *(.data)
    _edata = .;
  } > ram

  _e_romdata = _etext + SIZEOF(.data) ;
  FLASH_DB_START = _e_romdata % 65536 ?
                  (_e_romdata / 65536 + 1) * 65536 :
                  _e_romdata;
                  
  Is_MC2002EXT = 1;  /* set MC2002 Extended Flag, i.e. HC595 chip installed */
  
  .bss :
  {
	_start_bss = .;
	*(.bss)
        *(COMMON)
        _end = .;
  } > ram

  .nvram (NOLOAD):
  {
    *(.nvram)
  } > ram

  .heap ALIGN(2048) (NOLOAD) :
  {
        _heap_bottom = .;
        . += 94k;
       _heap_top    = .;
  } > ram
}
ENTRY(_start)