debug_asm.s

ReactOS是一些高手根据Windows XP的内核编写出的类XP。内核实现机理和API函数调用几乎相同。甚至可以兼容XP的程序。喜欢研究系统内核的人可以看一看。

/*
 * COPYRIGHT:         See COPYING in the top level directory
 * PROJECT:           ReactOS Run-Time Library
 * PURPOSE:           Debug Routines
 * FILE:              lib/rtl/i386/debug.S
 * PROGRAMER:         Alex Ionescu ([e-mail])
 */

.intel_syntax noprefix

/* GLOBALS ****************************************************************/

.globl _DbgBreakPoint@0
.globl _DbgBreakPointWithStatus@4
.globl _DbgUserBreakPoint@0
.globl _DebugService@20
.globl _DebugService2@12
.globl _DbgBreakPointNoBugCheck@0
.globl _RtlpBreakWithStatusInstruction@0

/* FUNCTIONS ***************************************************************/

.func DbgBreakPointNoBugCheck@0
_DbgBreakPointNoBugCheck@0:
    int 3
    ret
.endfunc

.func DbgBreakPoint@0
_DbgBreakPoint@0:
_DbgUserBreakPoint@0:
    int 3
    ret
.endfunc

.func DbgBreakPointWithStatus@4
_DbgBreakPointWithStatus@4:
    mov eax, [esp+4]

_RtlpBreakWithStatusInstruction@0:
    int 3
    ret 4
.endfunc

.func DebugService2@12
_DebugService2@12:

    /* Setup the stack */
    push ebp
    mov ebp, esp

    /* Call the interrupt */
    mov eax, [ebp+16]
    mov ecx, [ebp+8]
    mov edx, [ebp+12]
    int 0x2D
    int 3

    /* Restore stack */
    pop ebp
    ret 12
.endfunc

.func DebugService@20
_DebugService@20:

    /* Setup the stack */
    push ebp
    mov ebp, esp

    /* Save the registers */
    push ecx
    push ebx
    push edi
    push edi
    push ebx

    /* Call the Interrupt */
    mov eax, [ebp+8]
    mov ecx, [ebp+12]
    mov edx, [ebp+16]
    mov ebx, [ebp+20]
    mov edi, [ebp+24]
    int 0x2D
    int 3

    /* Restore registers */
    pop ebx
    pop edi
    pop edi
    pop ebx

    /* Return */
    leave
    ret 20
.endfunc