make.bat

一个收发短信收发设备进行短信收发的小程序

@echo off
echo.
echo jSMSEngine API Library.
echo Copyright (C) 2002-2006, Thanasis Delenikas, Athens / GREECE.
echo Visit http://www.jsmsengine.org for latest information.

if "%1" == "build" goto build
if "%1" == "clean" goto clean
if "%1" == "distro" goto distro
if "%1" == "betadistro" goto betadistro
if "%1" == "" goto help
goto help

:help
echo.
echo Build utility.
echo   Usage: make {build - clean - distro - betadistro}
echo     make build: Builds jSMSEngine API, examples, jSMSServer, javadoc.
echo     make clean: Removes all temporary files, jars, class, etc.
echo     make distro: Creates the distribution directory.
echo     make betadistro: Creates the Beta distribution directory (no RxTx or extra stuff).
goto end

:build
echo.
echo Building jSMSEngine API Library, please wait...
if not exist docs mkdir docs
javac -deprecation org\jsmsengine\*.java
jar c0fm jSMSEngine.jar org\jSMSEngine\jSMSEngine.mf org\jsmsengine\*.class
javac -deprecation examples\*.java
copy jSMSEngine.jar "C:\Program Files\Java\jdk1.5.0_02\jre\lib\ext"
copy jSMSEngine.jar "C:\Program Files\Java\jre1.5.0_02\lib\ext"
javadoc -private -d docs -windowtitle "jSMSEngine API" -doctitle "jSMSEngine API v2.0.5" -footer "<strong>jSMSEngine API v2.0.5</strong><br><strong>Web:</strong><a href="http://www.jsmsengine.org">http://www.jsmsengine.org</a></strong>" -overview extradocs\overview.html org\jsmsengine\*.java
echo.
echo Building jSMSServer application, please wait...
cd jSMSServer
javac -classpath ..\jSMSEngine.jar;.\ *.java
jar -c0fm jSMSServer.jar jSMSServer.mf *.class
cd ..
goto end

:distro
mkdir distro
if exist ..\_RxTxLinux-x86-32 xcopy ..\_RxTxLinux-x86-32 distro\RxTxLinux-x86-32  /s/e/i
if exist ..\_RxTxLinux-x86-64 xcopy ..\_RxTxLinux-x86-64 distro\RxTxLinux-x86-64  /s/e/i
if exist ..\_RxTxLinux-ia64 xcopy ..\_RxTxLinux-ia64 distro\RxTxLinux-ia64  /s/e/i
if exist ..\_RxTxWin32 xcopy ..\_RxTxWin32 distro\RxTxWin32  /s/e/i
if exist ..\_RxTxSolaris-32 xcopy ..\_RxTxSolaris-32 distro\RxTxSolaris-32  /s/e/i
if exist ..\_RxTxSolaris-64 xcopy ..\_RxTxSolaris-64 distro\RxTxSolaris-64  /s/e/i
xcopy docs distro\docs /s/e/i
xcopy org distro\org /s/e/i
xcopy examples distro\examples /s/e/i
xcopy jSMSServer distro\jSMSServer /s/e/i
xcopy misc distro\misc /s/e/i
xcopy extradocs distro\extradocs /s/e/i
copy jSMSEngine.jar distro
copy LICENSE.txt distro
copy make.bat distro
del distro\*.class /s > nul 2>&1
del distro\*.$ /s > nul 2>&1
cd distro
zip -r jSMSEngine *
cd ..
goto end

:betadistro
mkdir distro
xcopy org distro\org /s/e/i
xcopy examples distro\examples /s/e/i
xcopy jSMSServer distro\jSMSServer /s/e/i
copy jSMSEngine.jar distro
copy LICENSE.txt distro
copy make.bat distro
cd distro
zip -r jSMSEngine *
cd ..
goto end

:clean
echo Cleaning temporary files...
del *.jar /s> nul 2>&1
del *.bak /s> nul 2>&1
del *.class /s > nul 2>&1
del *.*~ /s > nul 2>&1
if exist docs rmdir docs /s/q > nul
if exist distro rmdir distro /s/q > nul
del jSMSServer\xml.in\*.xml > nul  2>&1
del jSMSServer\xml.out\*.xml > nul  2>&1
del jSMSServer\misc\*.raw > nul  2>&1
goto end

:end
echo.
echo ***** Done.