configure.in

RAM Defragmentation tools

dnl Process this file with autoconf to produce a configure script.
dnl and read http://www.ohse.de/uwe/articles/aal.html to find out
dnl why this project HAS to use autoconf and automake

AC_PREREQ(2.59)
AC_INIT(ramdefrag, 0.4.0, [e-mail])
AC_CONFIG_SRCDIR([src/callbacks.c])
AM_INIT_AUTOMAKE
AM_CONFIG_HEADER([config.h])

PACKAGE=${PACKAGE_NAME}
VERSION=${PACKAGE_VERSION}

dnl we would shurely go straight into hell if we believed in it for the following
AC_MSG_NOTICE([warning: this script uses maintainer-mode which is a Bad Thing.])
AM_MAINTAINER_MODE
dnl see also:
dnl http://www.gnu.org/software/automake/manual/html_node/maintainer-mode.html#maintainer-mode

AC_PROG_CC
AC_ISC_POSIX
AC_HEADER_STDC

pkg_modules="gtk+-2.0 >= 2.0.0"
PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

GETTEXT_PACKAGE=ramdefrag
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
ALL_LINGUAS="de fr sv"

AM_GLIB_GNU_GETTEXT

dnl check for getopt_long and use our replacement, if necessary
adl_FUNC_GETOPT_LONG

AC_CHECK_FUNCS([usleep snprintf], ,_
               AC_MSG_ERROR([function $ac_func is not available on this system!
                 write a workaround and send it to the maintainers.]))

AC_CHECK_LIB(fridge, beer, echo "Hmm?!",[
             echo "Warning: No beer found in fridge!";
             echo "We highly suggest that you rectify this situation immediately."
])

# try to set a disclaimer message for inclusion in ramdefrag.spec
# and debian/control if this is a cvs version:
CVS_DISCLAIMER_MSG=""
case "x${PACKAGE_VERSION}" in
  *cvs )
    CVS_DISCLAIMER_MSG="This version of the package is taken directly from the projects cvs."
    ;;
  *test )
    CVS_DISCLAIMER_MSG="This version of the package is built for testing purposes ONLY."
esac

AC_SUBST(CVS_DISCLAIMER_MSG)

dnl trying to get rid of acconfig.h
AH_TEMPLATE([GETTEXT_PACKAGE], [If you don't know what this means, just leave it alone.])

AC_OUTPUT([
Makefile
src/Makefile
po/Makefile.in
man/Makefile
debian/Makefile
ramdefrag.spec
])

# ========================================================================

echo
echo " $PACKAGE_NAME source configuration complete."
echo
echo "Now type:"
echo "  make           to build $PACKAGE_NAME"
echo "  make install   to install $PACKAGE_NAME"
echo
echo " Thanks for trying $PACKAGE_NAME, hope you'll enjoy it!"
echo