join.asp

Active Server Pages 网页制作教程看之前请传到ASP空间。或者本地用iis。或安装pws内有说明

<!-- #include virtual="/kjasp/func/DB.fun" -->
<%
mdbFile = "UsersPwd.mdb"
mdbPassword = "kj6688"

UserID = Request("UserID")
Password = Request("Password")
Password2 = Request("Password2")
Name = Request("Name")
Email = Request("Email")

' 检查是否为空白
If UserID = Empty Or Password = Empty Or Name = Empty Then
   ShowMessage "单元留白，不接受!"
End If

' 检查 Email
If InStr( Email, "@" ) = 0 Or Right(Email, 1) = "@" Or Left(Email, 1) = "@" Then
   ShowMessage "Email 错误，请重新输入!"
End If

' 检查两次输入的密码是否一致
If Password <> Password2 Then
   ShowMessage "两次输入的密码不一致!"
End If

' 检查此一 UserID 已有他人占用
SQL = "Select * From Users Where UserID='" & UserID & "'"
Set rs = GetSecuredMdbRecordset( mdbFile, SQL, mdbPassword )
If Not rs.EOF Then 	' 此一 UserID 码已被占用
   ShowMessage "此一「用户名称」已被占用，请重新输入!"
End If

' 检查此一 Email 是否已申请帐号
SQL = "Select * From Users Where Email='" & Email & "'"
Set rs = GetSecuredMdbRecordset( mdbFile, SQL, mdbPassword )
If Not rs.EOF Then 	' 此一 Email 已申请帐号
   ShowMessage "此一 Email 已申请帐号，请重新输入!"
End If

rs.AddNew
rs("UserID") = UserID
rs("Password") = Password
rs("Name") = Name
rs("Email") = Email
rs.Update

ShowMessage "您已经成为本站的会员了！"
%>


<% 
Sub ShowMessage( msg ) 
%>
   <CENTER>
   <H2><%=msg%><HR></H2>
   <FORM><INPUT Type=Button Value="返回上一页" OnClick="history.back();">
   </FORM>
   </CENTER>
<%
   Response.End 
End Sub 
%>