📄 setup.asp

📁 秘密网源代码传闻拉了 100W风投
💻 ASP
字号:
<!-- #include file="Conn.asp" -->
<%
Server.ScriptTimeout=SiteConfig("Timeout")	'设置脚本超时时间 单位:秒
ii=0
startime=timer()
if Request("menu")="out" then
	session.Abandon()
	response.redirect "login.asp"
end if
%>
<script type="text/javascript" src="../Utility/global.js"></script>
<script type="text/javascript" src="../Utility/Wo_Modal.js"></script>
<script type="text/javascript" src="../skin/<%=RequestCookies("skin")%>/Common.js"></script>
<Link rel="stylesheet" type="text/css" href="../skin/<%=RequestCookies("skin")%>/Common.css" />
<%
Function ShowRole(RoleID)
	if RoleID=1 then
		RoleID="管理员"
	elseif RoleID=2 then
		RoleID="超级组长"
	elseif RoleID=3 then
		RoleID="注册窝友"
	else
		RoleID=Conn.Execute("Select Name From [Wo_Roles] where RoleID="&RoleID&"")(0)
	end if
	ShowRole=RoleID
End Function
'''''''''''''''''''''''''''''''''''''''''''
Sub ShowRank(experience)
	sql="Select top 1 * From [Wo_Ranks] where PostingCountMin<="&experience&" order by PostingCountMin Desc"
	Set UserRank=Conn.Execute(sql)
		if UserRank.eof then
			RankName="未知等级"
			RankIconUrl="images/level/0.gif"
		else
			RankName=UserRank("RankName")
			RankIconUrl=UserRank("RankIconUrl")
		end if
	Set UserRank = Nothing
End Sub
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub AdminTop
	response.write "<body><div id=CommonListCell  style='PADDING-TOP:15px; PADDING-RIGHT:5px; PADDING-LEFT:5px; PADDING-BOTTOM:15px;text-align:center;'>"
End Sub
Sub ShowPage()
	PageUrl=ReplaceText(Request.QueryString,"PageIndex=([0-9]*)&","")
	if Request.Form<>empty then PageUrl=""&PageUrl&"&"&Request.Form&""
%>
	<script language="JavaScript">ShowPage(<%=TotalPage%>,<%=PageCount%>,"<%=PageUrl%>")</script>
<% end sub
Sub Alert(Message)
%>
	<script language="JavaScript">
	alert('<%=Message%>');
	history.back();
	</script>
	<script language="JavaScript">window.close();</script>
		
<%
	Response.End
End Sub
''''''''''''''''''''''''''''''''
Sub GroupList(ParentID)
	sql="select * from [Wo_Groups] where SortOrder>0 order by SortOrder"
	Rs.open sql,conn,1
		do while not Rs.eof
			ForumsList=ForumsList&"<optgroup label='"&rs("GroupName")&"'>"
			ii=ii+1
			ForumList Rs("GroupID"),0,ParentID
			ii=ii-1
			ForumsList=ForumsList&"</optgroup>"
		Rs.movenext
		loop
	Rs.close
End Sub

Sub ForumList(GroupID,ParentID,Selected)
	Selected=int(Selected)
	sql="select * From [Wo_Forums] where GroupID="&GroupID&" and ParentID="&ParentID&" and SortOrder>0 and IsActive=1 order by SortOrder"
	Set Rs1=Conn.Execute(sql)
	do while not rs1.eof
		if Rs1("ForumID")=Selected then
		ForumsList=ForumsList&"<option value='"&rs1("ForumID")&"' selected>"&string(ii,"　")&"-&raquo; "&rs1("ForumName")&"</option>"
		else
		ForumsList=ForumsList&"<option value='"&rs1("ForumID")&"'>"&string(ii,"　")&"-&raquo; "&rs1("ForumName")&"</option>"
		end if
		ii=ii+1
		ForumList GroupID,rs1("ForumID"),Selected
		ii=ii-1
		rs1.Movenext
	loop
	Set Rs1 = Nothing
End Sub

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function IsObjInstalled(strClassString)
	On Error Resume Next
	IsObjInstalled = False
	Set xTestObj = Server.CreateObject(strClassString)
	If 0 = Err Then IsObjInstalled = True
	Set xTestObj = Nothing
	On Error GoTo 0
End Function
'''''''''''''''''''''''''''''''''''''''''''
Function DelFile(DelFilePath)
	On Error Resume Next
	DelFile= False
	set MyFileObject=Server.CreateOBject("Scripting.FileSystemObject")
	MyFileObject.DeleteFile""&Server.MapPath(""&DelFilePath&"")&""
	Set MyFileObject= Nothing
	If 0 = Err or 53 = Err Then
		DelFile= True
	else
		Alert("出错讯息："&Err.Description&"\n"&DelFilePath&" 无法删除！")
	end if
	On Error GoTo 0
End Function

Function CheckSize(ByteSize)
	if ByteSize=>1073741824 then
		ByteSize=formatnumber(ByteSize/1073741824)&" GB"
	elseif ByteSize=>1048576 then
		ByteSize=formatnumber(ByteSize/1048576)&" MB"
	elseif ByteSize=>1024 then
		ByteSize=formatnumber(ByteSize/1024)&" KB"
	else
		ByteSize=ByteSize&" 字节"
	end if
	CheckSize=ByteSize
End Function

Sub ClubTree
	Set ClubTreeRs=Conn.Execute("Select * From [Wo_Groups] where SortOrder>0 order by SortOrder")
	do while not ClubTreeRs.eof
		ClubTreeList=ClubTreeList&"<div class=menuitems><a href=group.asp?GroupID="&ClubTreeRs("GroupID")&">"&ClubTreeRs("GroupName")&"</a></div>"
		ClubTreeRs.Movenext
	loop
	Set ClubTreeRs = Nothing
	response.write "<a href=group.asp>"&SiteConfig("SiteName")&"</a>"
End Sub

Sub error(Message)
'if IsResponseTop<>1 then HtmlTop
if Left(Message,4)<>"<li>" then Message="<li>"&Message
%>
<table width="900" border="0" cellspacing="0" cellpadding="0" align="center">
  <tr>
    <td><div id="CommonBreadCrumbArea"><%ClubTree%> → 提示信息</div></td>
  </tr>
</table>

<table cellspacing="1" cellpadding="0" width=900 id=CommonListArea align="center">
	<tr id=CommonListTitle3>
		<td width="100%" colspan="2" align="center">提示信息</td>
	</tr>
	<tr id=CommonListCell>
		<td valign="top" align="Left" colspan="2" height="122">
		<table cellspacing="0" cellpadding="0" width=900 border="0" align="center">
			<tr>
				<td width="83%" valign="top"><b>操作不成功的可能原因或建议：</b><ul><%=Message%></ul></td>
				<td width="17%"><img src="../images/err.gif" /></td>
			</tr>
		</table>
		</td>
	</tr>
	<tr align="center" id=CommonListCell>
		<td valign="center" colspan="2" height="30"><input onClick="history.back()" type="submit" value=" << 返 回 上 一 页 " /></td>
	</tr>
</table>
<%
End Sub

Sub Log(Message)
	MessageXML=MessageXML&"<Message>"&Message&"</Message>"&vbCrlf
	MessageXML=MessageXML&"<REMOTE_ADDR>"&Server.HTMLEncode(Request.ServerVariables("REMOTE_ADDR"))&"</REMOTE_ADDR>"&vbCrlf
	MessageXML=MessageXML&"<Request_Method>"&Server.HTMLEncode(Request.ServerVariables("Request_method"))&"</Request_Method>"&vbCrlf
	MessageXML=MessageXML&"<Server_Name>"&Server.HTMLEncode(Request.ServerVariables("server_name"))&"</Server_Name>"&vbCrlf
	MessageXML=MessageXML&"<Script_Name>"&Server.HTMLEncode(Request.ServerVariables("script_name"))&"</Script_Name>"&vbCrlf
	MessageXML=MessageXML&"<Query_String>"&Server.HTMLEncode(Escape(Request.ServerVariables("Query_String")))&"</Query_String>"&vbCrlf
	MessageXML=MessageXML&"<Request_Form>"&Server.HTMLEncode(Escape(Request.Form))&"</Request_Form>"&vbCrlf
	MessageXML=MessageXML&"<All_Http>"&Server.HTMLEncode(Request.ServerVariables("All_Http"))&"</All_Http>"&vbCrlf

	Conn.Execute("insert into [Wo_EventLog] (UserName,ErrNumber,MessageXML) values ('"&CookieUserName&"','"&Err.Number&"','"&MessageXML&"')")
End Sub
'''''''''''''''''''''''''''''''
Sub SendMail()

if MailSubject="" or MailBody="" or MailAddRecipient="" then Exit Sub
on error resume next
if SiteConfig("SelectMailMode")="JMail.Message" then
	Set JMail=Server.CreateObject("JMail.Message")
		JMail.Charset="gb2312"
		JMail.ContentType = "text/html"
		'JMail.ContentType = "text/plain"
		JMail.From = SiteConfig("SmtpServerMail")
		JMail.AddRecipient MailAddRecipient
		JMail.Subject = MailSubject
		JMail.Body = MailBody
		JMail.MailServerUserName = SiteConfig("SmtpServerUserName")
		JMail.MailServerPassword = SiteConfig("SmtpServerPassword")
		JMail.Send SiteConfig("SmtpServer")
	Set JMail=nothing
elseif SiteConfig("SelectMailMode")="CDO.Message" then
	Set CDO=Server.CreateObject("CDO.Message")
		CDO.From = SiteConfig("SmtpServerMail")
		CDO.To = MailAddRecipient
		CDO.Subject = MailSubject
		CDO.HtmlBody = MailBody
		'CDO.TextBody = MailBody
		CDO.HTMLBodyPart.Charset="gb2312"
		CDO.Send
	Set CDO=Nothing
end if

If Err Then Response.Write ""&Mailaddress&"邮件发送失败！错误原因：" & Err.Description & "<br>"
On Error GoTo 0

End Sub
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -