asp_to_html.asp

本软件可以把网站中的ASP文件转成HTML文件便于网站优化!

<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<%
	'禁用缓存
	Response.Buffer = true
	Response.ExpiresAbsolute = now()-1
	Response.Expires = 0
	Response.CacheControl = "no-cache"
	Response.AddHeader "Pragma", "No-Cache"
	Response.Clear()
	
	'==================================================
	'函数名：GetHttpPage
	'作  用：获取网页源码
	'参  数：HttpUrl ------网页地址
	'==================================================
	Function GetHttpPage(HttpUrl)
	
		'On Error Resume Next
	   If IsNull(HttpUrl)=True Or Len(HttpUrl)<18 Or HttpUrl="$False$" Then
		  GetHttpPage="$False$"
		  Exit Function
	   End If
	   Dim Http
	   Set Http=server.createobject("MSXML2.XMLHTTP")
	   Http.open "GET",HttpUrl,False
	   Http.Send()
	   'response.write HttpUrl &"<br>"
	   'response.end 
	   If Http.Readystate<>4 then
		  Set Http=Nothing 
		  GetHttpPage="$False$"
		  Exit function
	   End if
	   GetHTTPPage=bytesToBSTR(Http.responseBody,"GB2312")
	   Set Http=Nothing
	   If Err.number<>0 then
		  Err.Clear
	   End If
	End Function
	
	'==================================================
	'函数名：BytesToBstr
	'作  用：将获取的源码转换为中文
	'参  数：Body ------要转换的变量
	'参  数：Cset ------要转换的类型
	'==================================================
	Function BytesToBstr(Body,Cset)
	   Dim Objstream
	   Set Objstream = Server.CreateObject("adodb.stream")
	   objstream.Type = 1
	   objstream.Mode =3
	   objstream.Open
	   objstream.Write body
	   objstream.Position = 0
	   objstream.Type = 2
	   objstream.Charset = Cset
	   BytesToBstr = objstream.ReadText 
	   objstream.Close
	   set objstream = nothing
	End Function
	
	dim sBaseFolder	'固定目录(可选参数),如果该参数不为空且目录不存在则会创建。
	dim sFolderName	'文件夹(可选参数),如果该参数不位空且目录不存在则会创建。
	dim sFileName	'文件名(必选参数)。
	dim cUrl		'需静态生成的url地址(必选参数)。
	sBaseFolder=trim(Request("basefolder"))
	sFolderName=trim(Request("foldername"))
	sFileName=trim(Request("filename"))
	cUrl=trim(request("curl"))
	
	if len(sFileName)<1 then response.write "请提供文件名和文件夹名(文件夹可有可无，若无文件夹则在根目录生成)...":response.end 
	if len(cUrl)<1 then response.write "请提供URL...":response.end 
%>
<form name="frmcreate" method="post" action="FileCreate.asp">
<input type="hidden" name="basefolder" value="<%=sBaseFolder%>">
<input type="hidden" name="filename" value="<%=sFileName%>">
<input type="hidden" name="foldername" value="<%=sFolderName%>">
<input type="hidden" name="curl" size="50" value="<%=cUrl%>">
<textarea name="content"><%=GetHttpPage(cUrl)%></textarea>
<input type="hidden" name="ispost" value="yes">
</form>
<script>
<!--
	frmcreate.submit();
//-->
</script>