main.asm

电压控制程序,符合各种设备需要,核心程序,IBm专属

//======================================================================
//	The information contained herein is the exclusive property of
//	Sunnnorth Technology Co. And shall not be distributed, reproduced,
//	or disclosed in whole in part without prior written permission.
//	(C) COPYRIGHT 2003 SUNNORTH TECHNOLOGY CO.
//	ALL RIGHTS RESERVED
//	The entire notice above must be reproduced on all authorized copies.
//======================================================================

//======================================================================
//	工程名称：	ex09_asm_FIQ
//	功能描述：	《实验仪实验指导书》基础应用实验
//              FIQ中断
//				通过FIQ中断使用Timer,使用TimerA定时2秒,TimerB定时1秒，
//				通过IOA口相连的1*8LED显示出来
//  IDE环境：   SUNPLUS u'nSPTM  IDE 2.0.0（or later）
//	涉及的库：	CMacro1016.lib
//	组成文件：	main.asm
//	硬件连接：	LED_SEG的IOA0~7分别与a~h连接
//				LED_DIG的IOB6连接DIG5
//	维护记录：	2005-09-12	v1.0
//
//======================================================================

//======================================================================
//	文件名称：	main.asm
//	功能描述：	通过FIQ中断使用Timer,使用TimerA定时2秒,TimerB定时1秒，
//				通过IOA口相连的1*8LED显示出来
//	维护记录：	2005-09-12	v1.0
//=======================================================================
.DEFINE	P_IOA_Data			0x7000
.DEFINE	P_IOA_Buffer		0x7001
.DEFINE P_IOA_Dir			0x7002
.DEFINE P_IOA_Attrib		0x7003
.DEFINE P_IOB_Data			0x7005
.DEFINE P_IOB_Buffer		0x7006
.DEFINE P_IOB_Dir			0x7007
.DEFINE P_IOB_Attrib        0x7008

.DEFINE P_TimerA_Data		0x700A
.DEFINE P_TimerA_Ctrl		0x700B
.DEFINE P_TimerB_Data		0x700C
.DEFINE P_TimerB_Ctrl		0x700D
.DEFINE P_INT_Ctrl			0x7010
.DEFINE P_INT_Clear			0x7011
.DEFINE P_Watchdog_Clear	0x7012

.DEFINE C_FIQ_TMA			0x2000
.DEFINE C_FIQ_TMB			0x0800

.DEFINE	C_4096Hz			0x0004
.DEFINE	C_A1				0x0005
.DEFINE	C_2048Hz			0x0000
.DEFINE	C_B1				0x0030

.CODE

//==========================================================================
//	汇编格式：	_main
//	C格式：		int main(void);
//	实现功能：	通过FIQ中断使用Timer,使用TimerA定时2秒,TimerB定时1秒，
//				通过IOA口相连的1*8LED显示出来
//	入口参数：	无
//	出口参数：	无
//	破坏寄存器：r1,r2
//==========================================================================

.PUBLIC	_main
_main:
	int off							//关闭中断
	
	r1 = 0x00ff						//设置IOA7~0为同相高电平输出
	[P_IOA_Dir] = r1
	[P_IOA_Attrib] = r1
	[P_IOA_Data] = r1
	 
	r1 = 0x0040						//IOB输出高电平
	[P_IOB_Dir] = r1
	[P_IOB_Attrib] = r1
	[P_IOB_Data] = r1
	
	r1 = C_4096Hz | C_B1			//时钟源选择4096Hz，定时2秒，初值为0xdfff
	[P_TimerA_Ctrl] = r1
	r1 = 0xdfff
	[P_TimerA_Data] = r1
	
	r1 = C_4096Hz					//时钟源选择4096Hz，定时1秒，初值为0xefff
	[P_TimerB_Ctrl] = r1
	r1 = 0xefff
	[P_TimerB_Data] = r1
	
	r1 = C_FIQ_TMA | C_FIQ_TMB
	[P_INT_Ctrl] = r1				//打开TimerA和TimerB的FIQ中断
	
	int fiq							//打开FIQ总中断，关闭IRQ总中断
?Loop:
	r1 = 0x0001
	[P_Watchdog_Clear] = r1
	jmp ?Loop

.TEXT
//========================================================
//	汇编格式：	_FIQ
//	C格式：		无
//	实现功能：	FIQ中断服务程序
//	入口参数：	无
//	出口参数：	无
//	破坏寄存器：无
//========================================================
.PUBLIC _FIQ
_FIQ:
	push r1,r5 to [sp]
	r1 = [P_INT_Ctrl]				//读取中断标志
	test r1,C_FIQ_TMA				//是否为TimerA的FIQ中断？
	jnz ?L_FIQ_TMA					//是则跳转
	test r1,C_FIQ_TMB				//是否为TimerB的FIQ中断？
	jnz ?L_FIQ_TMB					//是则跳转
?L_FIQ_PWM:							//Fosc/1024的FIQ中断
	[P_INT_Clear] = r1
	pop r1,r5 from [sp]
	reti
?L_FIQ_TMA:							//TimerA的FIQ中断
	r1 = [P_IOA_Buffer]				//读取上次输出值
	r1 ^= 0x000f					//与0x000f异或，即将低四位数据取反
	[P_IOA_Buffer] = r1
	
	r1 = C_FIQ_TMA
	[P_INT_Clear] = r1				//清中断标志位
	pop r1,r5 from [sp]
	reti
?L_FIQ_TMB:							//TimerB的FIQ中断
	r1 = [P_IOA_Buffer]				//IOA7~4输出翻转
	r1 ^= 0x00f0					
	[P_IOA_Buffer] = r1
	
	r1 = C_FIQ_TMB
	[P_INT_Clear] = r1
	pop r1,r5 from [sp]
	reti