main.asm

电压控制程序,符合各种设备需要,核心程序,IBm专属

//=======================================================================
//	The information contained herein is the exclusive property of
//	Sunnnorth Technology Co. And shall not be distributed, reproduced,
//	or disclosed in whole in part without prior written permission.
//	(C) COPYRIGHT 2003 SUNNORTH TECHNOLOGY CO.
//	ALL RIGHTS RESERVED
//	The entire notice above must be reproduced on all authorized copies.
//=======================================================================

//=======================================================================
//	工程名称：	ex12_asm_IRQ5
//	功能描述：	《实验仪实验指导书》基础应用实验
//              IRQ5中断
//				使用IRQ5的2Hz、4Hz中断按照设定频率使LED闪烁
//  IDE环境：   SUNPLUS u'nSPTM  IDE 2.0.0（or later）
//	涉及的库：	CMacro1016.lib
//	组成文件：	main.asm
//	硬件连接：	LED_SEG的IOA0~7分别与a~h连接
//				LED_DIG的IOB6连接DIG5
//	维护记录：	2005-09-12	v1.0
//
//=======================================================================

//=======================================================================
//	文件名称：	main.asm
//	功能描述：	使用IRQ5的2Hz、4Hz中断按照设定频率使LED闪烁
//	维护记录：	2005-09-12	v1.0
//=======================================================================
.DEFINE	P_IOA_Data			0x7000
.DEFINE	P_IOA_Buffer		0x7001
.DEFINE P_IOA_Dir			0x7002
.DEFINE P_IOA_Attrib		0x7003
.DEFINE	P_IOB_Data			0x7005
.DEFINE	P_IOB_Buffer		0x7006
.DEFINE P_IOB_Dir			0x7007
.DEFINE P_IOB_Attrib		0x7008

.DEFINE P_INT_Ctrl			0x7010
.DEFINE P_INT_Clear			0x7011
.DEFINE P_Watchdog_Clear	0x7012

.DEFINE C_IRQ5_2Hz			0x0004
.DEFINE C_IRQ5_4Hz			0x0008

.CODE

//=======================================================================
//	汇编格式：	_main
//	C格式：		int main(void);
//	实现功能：	使用IRQ5的2Hz、4Hz中断按照设定频率使LED闪烁
//	入口参数：	无
//	出口参数：	无
//	破坏寄存器：r1,r2
//=======================================================================

.PUBLIC	_main
_main:
	int off							//关闭中断

	r1 = 0x00ff						//设置IOA7~0为同相高电平输出
	[P_IOA_Dir] = r1
	[P_IOA_Attrib] = r1
	[P_IOA_Data] = r1
	 
	r1 = 0x0040						//IOB输出高电平
	[P_IOB_Dir] = r1
	[P_IOB_Attrib] = r1
	[P_IOB_Data] = r1

	r1 = C_IRQ5_2Hz | C_IRQ5_4Hz
	[P_INT_Ctrl] = r1				//打开IRQ5的2Hz、4Hz时基中断
	
	int irq							//打开IRQ中断总使能，同时关闭FIQ中断
?Loop:
	r1 = 0x0001
	[P_Watchdog_Clear] = r1         //清看门狗
	jmp ?Loop

.TEXT
//=========================================================================
//	汇编格式：	_IRQ5
//	C格式：		无
//	实现功能：	IRQ5中断服务程序
//	入口参数：	无
//	出口参数：	无
//	破坏寄存器：无
//=========================================================================
.PUBLIC _IRQ5
_IRQ5:
	push r1,r5 to [sp]
	r1 = C_IRQ5_4Hz
	test r1,[P_INT_Ctrl]			//判断是否为IRQ5的4Hz中断？
	jnz ?L_IRQ5_4Hz					//是，则转向?L_IRQ5_4Hz	
?L_IRQ5_2Hz:						//2Hz时基中断
	r1 = [P_IOA_Buffer]
	r1 ^= 0x000f					//异或0x000f，即IOA口低四位数据取反
	[P_IOA_Data] = r1               //输出
	r1 = C_IRQ5_2Hz
	[P_INT_Clear] = r1              //清2Hz中断标志
	pop r1,r5 from [sp]
	reti
	
?L_IRQ5_4Hz:						//4Hz时基中断
	r1 = [P_IOA_Buffer]
	r1 ^= 0x00f0                    //IOA7~4数据取反
	[P_IOA_Data] = r1               //输出
	r1 = C_IRQ5_4Hz                  
	[P_INT_Clear] = r1              //清4Hz中断标志
	pop r1,r5 from [sp]
	reti