main.asm

电压控制程序,符合各种设备需要,核心程序,IBm专属

//======================================================================
//	The information contained herein is the exclusive property of
//	Sunnnorth Technology Co. And shall not be distributed, reproduced,
//	or disclosed in whole in part without prior written permission.
//	(C) COPYRIGHT 2003 SUNNORTH TECHNOLOGY CO.
//	ALL RIGHTS RESERVED
//	The entire notice above must be reproduced on all authorized copies.
//======================================================================

//======================================================================
//	工程名称：	ex14_asm_IRQ3_EXT1_EXT2
//	功能描述：	《实验仪实验指导书》基础应用实验
//              外部中断EXT1、EXT2
//				通过IRQ3外部中断EXT1、EXT2点亮相应的LED
//  IDE环境：   SUNPLUS u'nSPTM  IDE 2.0.0（or later）
//	涉及的库：	CMacro1016.lib
//	组成文件：	main.asm
//	硬件连接：	LED_SEG接口的IOA0~7与a~h分别连接
//				LED_DIG接口的IOB6与DIG5连接
//				IOB2、IOB3分别连接KEYPAD接口的COL3和COL4
//				KEYPAD接口的ROW接地
//	维护记录：	2005-09-12	v1.0
//
//======================================================================

//======================================================================
//	文件名称：	main.asm
//	功能描述：	通过IRQ3外部中断EXT1、EXT2点亮相应的LED
//	维护记录：	2005-09-12	v1.0
//======================================================================
.DEFINE	P_IOA_Data			0x7000
.DEFINE	P_IOA_Buffer		0x7001
.DEFINE P_IOA_Dir			0x7002
.DEFINE P_IOA_Attrib		0x7003
.DEFINE P_IOB_Data			0x7005
.DEFINE P_IOB_Buffer		0x7006
.DEFINE P_IOB_Dir			0x7007
.DEFINE P_IOB_Attrib		0x7008

.DEFINE P_INT_Ctrl			0x7010
.DEFINE P_INT_Clear			0x7011
.DEFINE P_Watchdog_Clear	0x7012

.DEFINE C_IRQ3_KEY			0x0080
.DEFINE C_IRQ3_EXT1			0x0100
.DEFINE C_IRQ3_EXT2			0x0200

.RAM

.CODE

//========================================================
//	汇编格式：	_main
//	C格式：		int main(void);
//	实现功能：	通过IRQ3外部中断EXT1、EXT2点亮相应的LED
//	入口参数：	无
//	出口参数：	无
//	破坏寄存器：r1,r2
//========================================================

.PUBLIC	_main
_main:
	int off							//关闭中断
	
	r1 = 0x00ff						//设置IOA0~7为同相输出
	[P_IOA_Dir] = r1
	[P_IOA_Attrib] = r1
	r1 = 0x0000
	[P_IOA_Data] = r1				//初始化IOA0~7输出为低电平
	
	r1 = 0x0040						//IOB6输出高电平，IOB2、IOB3上拉输入
	[P_IOB_Dir] = r1
	[P_IOB_Attrib] = r1
	r1 = 0x004C
	[P_IOB_Data] = r1
	
	r1 = C_IRQ3_EXT1 |C_IRQ3_EXT2
	[P_INT_Ctrl] = r1				//打开EXT1和EXT2中断
	
	int irq							//打开IRQ总中断，关闭FIQ总中断
?Loop:
	r1 = 0x0001
	[P_Watchdog_Clear] = r1         //清看门狗
	jmp ?Loop

.TEXT
//========================================================
//	汇编格式：	_IRQ3
//	C格式：		无
//	实现功能：	IRQ3中断服务程序
//	入口参数：	无
//	出口参数：	无
//	破坏寄存器：无
//========================================================
.PUBLIC _IRQ3
_IRQ3:
	push r1,r5 to [sp]
	r1 = C_IRQ3_EXT1
	test r1,[P_INT_Ctrl]
	jnz ?L_IRQ3_Ext1				//测试为EXT1中断则转向?L_IRQ3_Ext1
	r1 = C_IRQ3_EXT2
	test r1,[P_INT_Ctrl]
	jnz ?L_IRQ3_Ext2				//为EXT2中断则转向?L_IRQ3_Ext2
?L_IRQ3_Key:
	r1 = C_IRQ3_KEY
	[P_INT_Clear] = r1				//清中断标志位
	pop r1,r5 from [sp]
	reti
?L_IRQ3_Ext2:
	r1 = 0x00f0
	[P_IOA_Data] = r1				//IOA4~7输出高电平
	r1 = C_IRQ3_EXT2
	[P_INT_Clear] = r1              //清中断标志
	pop r1,r5 from [sp]
	reti
?L_IRQ3_Ext1:
	r1 = 0x000f
	[P_IOA_Data] = r1				//IOA0~3输出高电平
	r1 = C_IRQ3_EXT1
	[P_INT_Clear] = r1              //清中断标志
	pop r1,r5 from [sp]
	reti