class_sql.asp

海洋分类信网程序是由海洋城市设计工作室基于ASP+Access/Mssql技术开发的分类信息程序

<% 
class SQLString 
'************************************ 
'变量定义 
'************************************ 
'sTableName ---- 表名 
'iSQLType ----SQL语句类型：0-增加，1-更新，2-删除,3-查询 
'sWhere ---- 条件 
'sOrder ---- 排序方式 
'sSQL ----值 
Private sTableName,iSQLType,sWhere,sOrder,sSQL 
'************************************ 
'类初始化/结束 
'************************************ 
Private Sub Class_Initialize() 
 sTableName="" 
 iSQLType=0 
 sWhere="" 
 sOrder="" 
 sSQL="" 
End Sub 
Private Sub Class_Terminate() 
End Sub 
'************************************ 
'属性 
'************************************ 
'设置表名的属性 
Public Property Let TableName(value) 
 sTableName=value 
End Property 
'设置条件 
Public Property Let Where(value) 
 sWhere=value 
End Property 
'设置排序方式 
Public Property Let Order(value) 
 sOrder=value 
End Property 
'设置查询语句的类型 
Public property Let SQLType(value) 
iSQLType=value 
select case iSQLType
 case 0 : sSQL="insert into #0 (#1) values (#2) " 
 case 1 : sSQL="update #0 set #1=#2 "
 case 2 : sSQL="delete from #0 "
 case 3 : sSQL="select #1 from #0 "
end select 
End Property 
'************************************ 
'函数 
'************************************ 
'增加字段(字段名称，字段值) 
Public Sub AddField(sFieldName,sValue)
 select case iSQLType
  case 0 
   sSQL=replace(sSQL,"#1",sFieldName & ",#1") 
   sSQL=replace(sSQL,"#2","'" & sValue & "',#2")
  case 1 
   sSQL=replace(sSQL,"#1",sFieldName)
   sSQL=replace(sSQL,"#2","'" & sValue & "',#1=#2")
  case 3 
   sSQL=replace(sSQL,"#1",sFieldName & ",#1")
 End Select 
End Sub 
'返回SQL语句 
Public Function ReturnSQL()
 sSQL=replace(sSQL,"#0",sTableName)
 select case iSQLType 
  case 0 
   sSQL=replace(sSQL,",#1","")
   sSQL=replace(sSQL,",#2","")
  case 1 
   sSQL=replace(sSQL,",#1=#2","")
  case 3 
   sSQL=replace(sSQL,",#1","")
 end Select 
 if sWhere<>"" then sSQL=sSQL & " where " & sWhere end if
 if sOrder<>"" then sSQL=sSQL & " order by " & sOrder
 ReturnSQL=sSQL
End Function
  
'清空语句 
Public Sub Clear()
 sTableName="" 
 iSQLType=0 
 sWhere="" 
 sOrder="" 
 sSQL="" 
End Sub 
End class 
%>