minmx68k.lib

open source of basic interpreter of 68

*
*  minmx68k      support routines for min/max functions (68000)
*
*  This library file supports the following functions:
*
*  min(a, b)  returns the smaller (signed) of A and B
*  max(a, b)  returns the larger (signed) of A and B
*  minu(a, b)  returns the smaller (unsigned) of A and B
*  maxu(a, b)  returns the larger (unsigned) of A and B
*
*  Upon entry, A is in register D0 and B is in the TOS (pointed to
*  by A4).  Upon exit, the desired value is returned in D0 and the
*  top element of the stack has been dropped.
*
*  15 Oct 2000  Doug Kelly
*  BHS removed, CMP rearranged
*

_min
	cmp.l	(a4),d0		test values
	ble	_minx		branch if d0 <= (a4)
	move.l	(a4),d0		get smaller value
_minx
	tst.l	(a4)+		burn stack value
	rts


_max
	cmp.l	(a4),d0		test values
	bge	_minx		branch if d0 >= (a4)
	move.l	(a4),d0		get larger value
	bra	_minx		common return


_minu
	cmp.l	(a4),d0		test values
	bls	_minx		branch if d0 <= (a4) unsigned
	move.l	(a4),d0		get smaller value
	bra	_minx		common return


_maxu
	cmp.l	(a4),d0		test values
	bcc	_minx		branch if d0 >= (a4) unsigned
	move.l	(a4),d0		get larger value
	bra	_minx		common return