main.asm

SACM_D10 for SPCE061A.rar,凌阳单片机SPCE061A的语音编码资料

//======================================================================
//	工程名称：	S720_ASM.spj
//	功能描述：	S720语音播放范例--汇编语言
//				连续播放三段语音
//  IDE环境：   SUNPLUS u'nSPTM  IDE 2.0.0（or later）
//	涉及的库：	CMacro1016.lib
//              SACM_D10.lib
//	组成文件：	main.asm, SACM_S720_User_ASM.asm, SACM_S720.asm
//				SPCE061A.inc, S720.inc
//	维护记录：	2006-10-16	v1.0,  by Qwerty
//======================================================================
.INCLUDE SPCE061A.inc
.INCLUDE S720.INC

.PUBLIC F_PlaySnd
.PUBLIC _main

.CODE
//========================================================================
//	语音播放函数，参数 R1 为待播放的语音序号，起始序号为0
//========================================================================
F_PlaySnd:
	push r1, r3 to [sp]
	call F_SACM_S720_Initial				// S720初始化
	r2 = DAC_1 + DAC_2						
	r3 = RAMP_UP_DN
	call F_SACM_S720_Play					// 播放第R1段语音，由DAC1和DAC2输出(R2)，采用渐入渐出方式(R3)
?Loop:
	r1 = 0x01
	[P_Watchdog_Clear] = r1					// 清看门狗
	call F_SACM_S720_ServiceLoop			// 执行语音解码
	call F_SACM_S720_Status					// 检测播放是否完成
	test r1, STATUS_PLAY
	jnz ?Loop	
	pop r1, r3 from [sp]
retf

//========================================================================
//	主函数
//========================================================================
_main:
?Loop:
	r1 = 0									// 播放第一段语音
	call F_PlaySnd
	r1 = 1									// 播放第二段语音
	call F_PlaySnd
	r1 = 2									// 播放第三段语音
	call F_PlaySnd
	goto ?Loop
retf


//========================================================================
//	中断服务程序
//========================================================================
.PUBLIC _FIQ
.TEXT
_FIQ:
	push r1 to [sp]
	r1 = C_FIQ_TMA
	[P_INT_Clear] = r1						// 清中断请求标志
	call F_SACM_S720_ISR					// 调用中断服务子程序
	pop r1 from [sp]
reti