commctrop.bas

群里的通讯录管理 供参考 学习专用 无其他商业意义 源码较为简单

Attribute VB_Name = "commCtrOp"
'***********************************************************************
'* 文件名： commCtrOp.bas
'* 说  明： 控件通用操作模块
'* 版  本： 2005.12.16 颜志军 初版
'***********************************************************************

Option Explicit

'***********************************************************************
'* 过程名：DspPhoto
'* 功  能：显示像片
'* 参  数：String                       像片名路径
'* 版  本：2005.12.15 颜志军 初版
'***********************************************************************
Public Sub DspPhoto(ByRef imageCtl As Image, ByVal filename As String)
    '变量定义
    Dim pic As Picture          'PICTURE 属性
    Dim picH As Long            '图片高
    Dim picW As Long            '图片宽
    Dim picRate As Double       '图片长宽比例
    Dim imgH As Long            '控件高
    Dim imgW As Long            '控件宽
    Dim imgLeft As Long         '控件左侧位置
    Dim imgMid As Long          '控件水平中间位置
    
    On Error Resume Next
    
    '载入图片并取得图片长宽信息
    Set pic = LoadPicture(filename)
    picH = pic.Height
    picW = pic.Width
    '计算图片长宽比
    picRate = picH / picW
    
    '取得控件当前信息
    imgH = imageCtl.Height                      '控件高度
    imgLeft = imageCtl.Left                     '控件当前左侧位置
    imgMid = imgLeft + imageCtl.Width / 2       '控件当前中间位置
    
    '计算控件新位置及宽度
    imgW = imgH / picRate                       '调整后的控件宽度
    imgLeft = imgMid - imgW / 2                 '调整后的控件左侧起点
    If imgLeft < 0 Then
        imgLeft = 0
    End If
    
    '调整控件
    imageCtl.Width = imgW
    imageCtl.Left = imgLeft
    
    '显示图片
    imageCtl.Picture = pic
End Sub