ex2.8.txt

通过实例详细介绍Ansys在实际工程中的应用

!2.8  偏心受压杆的大变形分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项，分析类型，实常数和材料参数等
/PREP7
/TITLE, EX2.8, LARGE DEFLECTION ECCENTRIC COMPRESSION OF SLENDER COLUMN
C***      STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PG. 263, PROB. 1
ANTYPE,STATIC
NLGEOM,ON
ET,1,BEAM54
R,1,2167.7,54.106e4,14.732,42.672
RMORE,,,,-14.732,,-14.732
MP,EX,1,207E3
MP,NUXY,1,0.3
! (2) 定义节点
N,1
N,5,,1524
FILL
! (3) 定义单元
E,1,2
EGEN,4,1,1
! (4) 施加位移约束和荷载
D,1,ALL
F,5,FY,-17793
FINISH
! (5) 进入求解模块求解
/SOLU
CNVTOL,F,,1E-4
CNVTOL,M,,1E-1
OUTPR,,LAST
SOLVE
FINISH
! (6) 在后处理模块，提取计算结果
/POST1
END_NODE = NODE (0,3048/2,0)
*GET,DEF,NODE,END_NODE,U,X
ETABLE,TENS,NMISC,1
ETABLE,COMP,NMISC,2
*GET,STS_TENS,ELEM,1,ETAB,TENS
*GET,STS_COMP,ELEM,1,ETAB,COMP
! (7) 将计算结果输出到文件
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFLECTI','STRSS_TE','STRSS_CO'
LABEL(1,2) = 'ON (mm) ','NS (MPa)','MP (MPa)'
*VFILL,VALUE(1,1),DATA,3.21,16.968,-16.90
*VFILL,VALUE(1,2),DATA,ABS(DEF),STS_TENS,STS_COMP
*VFILL,VALUE(1,3),DATA,ABS(DEF/3.21),ABS(STS_TENS/16.968),ABS(STS_COMP/16.9)
/COM
/OUT, EX2_8, out
/COM,-------------------  EX2.8  RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST, EX2_8, out