ex6.7.txt

通过实例详细介绍Ansys在实际工程中的应用

!6.7  两边简支开口柱壳在集中力作用下的大变形曲屈
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 设置工程选项,分析类型,实常数,材料参数
/FileName, EX6.7
/PREP7
smrt,off
/TITLE, EX6.7, SNAP-THROUGH BUCKLING OF A HINGED SHELL
:COM    CHANG, C.C.,"PERIODICALLY RESTARTED QUASI-NEWTON UPDATES IN
:COM    IN CONSTANT ARC-LENGTH METHOD", COMPUTERS AND STRUCTURES,
:COM    VOL. 41, NO. 5, PP. 963-972, 1991.
ANTYPE,STATIC
ET,1,SHELL63,,1
R,1,6.350
MP,EX,1,3102.75
MP,NUXY,1,0.3
! (2)定义节点,关键点,面,并将面划分为面单元
:COM  CREATE FINITE ELEMENT MODEL
R1 = 2540
L  = 254
PI = 4*ATAN(1)
THETA = 0.1*180/PI
CSYS,1
N,1,R1,90
N,2,R1,90,L
K,1,R1,90
K,2,R1,(90-THETA)
K,3,R1,90,L
K,4,R1,(90-THETA),L
ESIZE,,2
A,1,3,4,2
/View,1,1,1,1
/PNUM,NODE,1
AMESH,1
NUMMRG,NODE
EPLOT
! (3)施加位移边界条件
:COM  APPLY BOUNDARY CONDITIONS
NSEL,S,LOC,Z,0
DSYM,SYMM,Z
NSEL,S,LOC,Y,90
DSYM,SYMM,X
NSEL,S,LOC,Y,(90-THETA)
D,ALL,UX,,,,,UY,UZ
NSEL,ALL
F,1,FY,-250
FINISH
! (4)在求解模块定义荷载后求解
:COM   SOLUTION PHASE
:COM SINCE THE SOLUTION OUTPUT IS SUBSTANTIAL IT IS DIVERTED TO A SCRATCH FILE
/OUTPUT,SCRATCH
/SOLU
NLGEOM,ON
OUTRES,,1
NSUBST,30
ARCLEN,ON,4
SOLVE
FINISH
/OUTPUT
! (5)在时间历程后处理模块,处理位移计算结果
:COM   POSTPROCESSING PHASE
/POST26
NSOL,2,1,U,Y
NSOL,3,2,U,Y
PROD,4,1,,,LOAD,,,4*250
PROD,5,2,,,,,,-1
PROD,6,3,,,,,,-1
*GET,UY1,VARI,2,EXTREM,VMIN
*GET,UY2,VARI,3,EXTREM,VMIN
! (6)在时间历程后处理模块,会替荷载-变形曲线
PRVAR,2,3,4
/AXLAB,X, DEFLECTION (MM)
/AXLAB,Y, TOTAL LOAD (N)
/GRID,1
/XRANGE,0,35
/YRANGE,-500,1050
XVAR,5
PLVAR,4
/NOERASE
XVAR,6
PLVAR,4
/ERASE
! (7) 定义数组变量,保存计算结果后输出到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'UY @A ','UY @B '
LABEL(1,2) = 'mm ','mm '
*VFILL,VALUE(1,1),DATA,-30,-26
*VFILL,VALUE(1,2),DATA,UY1,UY2
*VFILL,VALUE(1,3),DATA,ABS(UY1/30),ABS(UY2/26)
/COM
/OUT, EX6_7, out
/COM,-------------------  EX6.7 RESULTS COMPARISON ---------------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.1,'  ',F10.1,'   ',1F5.3)
/COM,-------------------------------------------------------------
/OUT
FINISH
*LIST, EX6_7, out
/DELETE,SCRATCH