ex6.5.txt

通过实例详细介绍Ansys在实际工程中的应用

!6.5  两端简支开口柱壳在自重作用下的静力分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR,NOSTART
! (1)设置工程选项,分析类型,实常数,材料参数
/FileName,EX6.5
/PREP7
smrt,off
/TITLE, EX6.7, BARREL VAULT ROOF UNDER SELF-WEIGHT
/COM, REF: COOK, CONCEPTS AND APPL. OF F.E.A., 2ND ED., 1981, PP. 284-287.
ANTYPE,STATIC
ET,1,SHELL93
R,1,0.25
MP,EX,1,4.32E8
MP,NUXY,1,0.0
MP,DENS,1,36.7347
! (2)在柱坐标系下定义关键点,柱面并对其进行单元划分
CSYS,1
K,1,25,50
K,2,25,50,25
KGEN,2,1,2,1,,40
A,1,3,4,2
ESIZE,,4
/View,1,1,1,1
AMESH,1
! (3)选择对称边界上的点,施加对称边界条件,对端部边界点施加墙体约束
CSYS,0
NSEL,S,LOC,X
DSYM,SYMM,X
NSEL,S,LOC,Z
DSYM,SYMM,Z
NSEL,S,LOC,Z,25
D,ALL,UX,0,,,,UY,ROTZ
NSEL,ALL
ACEL,,9.8
FINISH
! (4)进入求解模块求解
/SOLU
SOLVE
FINISH
! (5)进入后处理模块提取计算结果
/POST1
NSEL,S,NODE,,1,2,1
ESLN,S
PRNSOL,U,COMP
*GET,UYA,NODE,1,U,Y
*GET,UXA,NODE,1,U,X
! (6)在柱坐标系下显示,提取计算结果
RSYS,1
SHELL,TOP
PRNSOL,S,COMP
*GET,SIGZ_TOP,NODE,1,S,Z
*GET,SIGY_TOP,NODE,2,S,Y
! (7)提取壳体下表面的应力计算结果
SHELL,BOT
PRNSOL,S,COMP
*GET,SIGZ_BOT,NODE,1,S,Z
*GET,SIGY_BOT,NODE,2,S,Y
! (8)定义数组,将计算结果保存到数组,然后将数组内容输出的计算结果文件
*DIM,LABEL,CHAR,6,2
*DIM,VALUE,,6,3
LABEL(1,1) = 'UYA     ','UXA     ','SIGZ, TO','SIGZ, BO','SIGTH,TO','SIGTH,BO'
LABEL(1,2) = '     (m)','     (m)','P_A (Pa)','T_A (Pa)','P_B (Pa)','T_B (Pa)'
*VFILL,VALUE(1,1),DATA,-0.3019,-0.1593,215570,340700,191230,-218740
*VFILL,VALUE(1,2),DATA,UYA,UXA,SIGZ_TOP,SIGZ_BOT,SIGY_TOP,SIGY_BOT
*VFILL,VALUE(1,3),DATA,ABS(UYA/0.3019),ABS(UXA/0.1593),ABS(SIGZ_TOP/215570)
*VFILL,VALUE(4,3),DATA,ABS(SIGZ_BOT/340700),ABS(SIGY_TOP/191230),ABS(SIGY_BOT/218740)
/COM
/OUT, EX6_5, out
/COM,-------------------  EX6.5 RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F12.4,'  ',F12.4,'   ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX6_5, out