ex9.2.txt

来自「通过实例详细介绍Ansys在实际工程中的应用」· 文本 代码 · 共 108 行

!9.2  薄膜二维非轴对称自由振动分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART

/FILENAME, EX9.2
/PREP7
/TITLE, EX9.2, NONAXISYMMTRIC VIBRATION OF A STRETCHED CIRCULAR MEMBRANE (HARMONIC ELEMENTS)
C***     VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., ART. 69, PAGE 438
ET,1,SHELL61
R,1,1.27e-6
MP,EX,1,207E9
MP,NUXY,1,0
MP,ALPX,1,5.5556E-6
MP,DENS,1,7801.6

K,1
K,2,76.2e-3
L,1,2
LESIZE,1,,,9
LMESH,1

NSEL,S,LOC,X,0
D,ALL,UX
NSEL,S,LOC,X,76.2e-3
D,ALL,UX,,,,,UY
NSEL,ALL
M,ALL,UY
D,ALL,UZ
TREF,0
BFUNIF,TEMP,-12
FINISH

/SOLU
ANTYPE,STATIC
PSTRES,ON
OUTPR,BASIC,ALL
SOLVE
FINISH

/SOLU
ANTYPE,MODAL
PSTRES,ON
MXPAND,3
MODOPT,REDUC
MODE,0
SOLVE
FINISH

/POST1
/WINDOW,1,LTOP
SET,1,1
PLDISP,1
/NOERASE
*GET,F11,MODE,0,FREQ
/WINDOW,1,OFF
/WINDOW,4,RBOT
SET,1,2
PLDISP,1
*GET,F12,MODE,2,FREQ
/WINDOW,4,OFF
FINISH

/SOLU
MODE,1
SOLVE
FINISH
/POST1
/WINDOW,2,RTOP
SET,1,1
PLDISP,1
*GET,F21,MODE,0,FREQ
/WINDOW,2,OFF
FINISH

/SOLU
MODE,2
SOLVE
FINISH

/POST1
/WINDOW,3,LBOT
SET,1,1
PLDISP,1
*GET,F31,MODE,0,FREQ
*status,parm

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'F(0,1) ','F(1,1) ','F(2,1) ','F(0,2)'
LABEL(1,2) = 'Hz ','Hz ','Hz ','Hz '
*VFILL,VALUE(1,1),DATA,211.1,336.5,450.9,484.7
*VFILL,VALUE(1,2),DATA,F11,F21,F31,F12
*VFILL,VALUE(1,3),DATA,ABS(F11/211.1),ABS(F21/336.5),ABS(F31/450.9),ABS(F12/484.7)
/COM
/OUT, EX9_2, out
/COM,-------------------  EX9.2 RESULTS COMPARISON -------------
/COM,
/COM,                 |    TARGET   |    ANSYS   |    RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.1,'  ',F11.1,'   ',1F6.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST, EX9_2, out