ex9.3.txt

通过实例详细介绍Ansys在实际工程中的应用

!9.3  薄膜三维非轴对称振动分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART

/FILNAME, EX9.3
/PREP7
/TITLE, EX9.3, NONAXISYM. VIBR. OF A STRETCHED CIRCULAR MEMBRANE (STATIC)
!         VIBRATION PROBS. IN ENGR., TIMOSHENKO, PAGE 439, ARTICLE 69
ANTYPE,STATIC
ET,1,SHELL41,,1
MP,EX,1,207E9
MP,NUXY,1,0
MP,ALPX,1,5.5556E-6
MP,DENS,1,7801.6
R,1,1.27e-6

CSYS,1
N,1,.0001
N,10,76.2e-3
FILL

NGEN,4,10,1,10,1,,10
NROTAT,ALL
E,1,2,12,11
! 单元生成命令格式：EGEN, ITIME, NINC, IEL1, IEL2, IEINC, MINC, TINC, RINC, CINC, SINC, DX, DY, DZ
EGEN,3,10,-1
EGEN,9,1,-3

NSEL,S,LOC,Y,0
! DEFINE EDGE COMPONENTS FOR CYCLIC SYMM. MACRO
CM,RIGHT,NODE
NSEL,S,LOC,Y,30
CM,LEFT,NODE
NSEL,ALL
/NOPR
CYCGEN
/GOPR
D,ALL,ALL,0
TREF,0
BFUNIF,TEMP,-12
FINISH

/SOLU
PSTRES,ON
SOLVE
FINISH

/PREP7
/TITLE, EX9_3(2), NONAXISYM. VIBR. OF A STRETCHED CIRCULAR MEMBRANE (MODAL)
ANTYPE,MODAL
MODOPT,LANB,4,1,1000
MXPAND,4
PSTRES,ON

DDEL,ALL,ALL
NSEL,S,LOC,Y,0
NSEL,A,LOC,Y,30
D,ALL,UX,,,,,UY
NSEL,S,LOC,X,76.2e-3
D,ALL,ALL,0
NSEL,ALL
/REPLOT
FINISH

/SOLU
/OUTPUT,SCRATCH
0度共分NSECTOR个扇区
CYCSOL,0,1,12,'RIGHT'
! MACRO, NODAL DIAMETER 0 TO 1, WITH 30 DEG. SECTORS
/OUTPUT
FINISH

/POST1
SET,1,1
*GET,F01_1,ACTIVE,,SET,FREQ
SET,1,2
*GET,F02_1,ACTIVE,,SET,FREQ
SET,2,1
*GET,F11_1,ACTIVE,,SET,FREQ
SET,2,2
*GET,F11_2,ACTIVE,,SET,FREQ
SET,2,3
*GET,F12_1,ACTIVE,,SET,FREQ
SET,2,4
*GET,F12_2,ACTIVE,,SET,FREQ
FINISH

/NOPR
/POST1
EXPAND,12
/VIEW,,1,1,1
/VUP,1,Z
/GLINE,,-1
/TRIAD,OFF
SET,1,2
/TITLE, EX9_3(3), STRETCHED CIRCULAR MEMBRANE - NODAL DIAM 0, MODE 2
PLNSOL,U,Z
SET,2,2
/TITLE, EX9_3(4), STRETCHED CIRCULAR MEMBRANE - NODAL DIAM 1, MODE 2
PLNSOL,U,Z
FINISH

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'F(0,1) ','F(0,2) ','F(1,1) ','F(1,2)'
LABEL(1,2) = 'Hz ','Hz ','Hz ','Hz '
*VFILL,VALUE(1,1),DATA,211.1,484.7,336.5,616.1
*VFILL,VALUE(1,2),DATA,F01_1,F02_1,F11_1,F12_1
*VFILL,VALUE(1,3),DATA,ABS(F01_1/211.1),ABS(F02_1/484.7),ABS(F11_1/336.5),ABS(F12_1/616.1)
/COM
/OUT, EX9_3, out
/COM,-------------------  EX9.3 RESULTS COMPARISON -------------
/COM,
/COM,                 |    TARGET   |    ANSYS   |    RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.1,'  ',F11.1,'   ',1F6.3)
/COM,----------------------------------------------------------
/OUT
/DELETE,PRSMEMB,tri
/DELETE,PRSMEMB,emat
/DELETE,PRSMEMB,esav
/DELETE,PRSMEMB,full
/DELETE,PRSMEMB,mode
/DELETE,PRSMEMB,rst
/DELETE,SCRATCH
*LIST, EX9_3, out