ex9.1.txt

通过实例详细介绍Ansys在实际工程中的应用

!9.1  圆形张紧薄膜的自由振动
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART

/FileName, EX9.1
/PREP7
/TITLE, EX9.1, VIBRATION OF A STRETCHED CIRCULAR MEMBRANE
C***   VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE  439, EQN. 182
ANTYPE,STATIC
PSTRES,ON
ET,1,SHELL51
MP,EX,1,207E9
MP,PRXY,1,0.3
MP,DENS,1,7805
R,1, 0.254e-3

N,1
N,10,0.381
FILL
E,1,2
EGEN,9,1,1

D,1,UX,,,,,ROTZ
D,10,UY,,,,,UZ
F,10,FX,41924
FINISH

/SOLU
OUTPR,BASIC,1
SOLVE
FINISH

/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,9,ETAB,STRS
FINISH

/SOLU
ANTYPE,MODAL
PSTRES,ON
MXPAND,3
MODOPT,REDUC,,,,9
M,1,UY,9
SOLVE

*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ

*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'SIG,R   ','f1,     ','f2,     ','f3,     '
LABEL(1,2) = 'MPa     ','Hz      ','Hz      ','Hz    '
*VFILL,VALUE(1,1),DATA,68.95,94.3854,216.73,339.77
*VFILL,VALUE(1,2),DATA,STRSS/1e6,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,(STRSS/1e6/68.95),(FREQ1/94.3854),(FREQ2/216.73),(FREQ3/339.77)
/COM
/OUT, EX9_1, out
/COM,-------------------  EX9.1 RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX9_1, out