ex9.7.txt

通过实例详细介绍Ansys在实际工程中的应用

!9.7  用实体单元分析圆环的振动
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,分析类型,单元类型,实常数,模态求解选项和材料参数
/FILENAME, EX9.7
/PREP7
/TITLE, EX9.7, RADIAL VIBRATIONS OF A CIRCULAR RING FROM AN AXISYMMETRIC MODEL
C***   VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE  425, ART. 68
ANTYPE,MODAL
ET,1,PLANE25
MXPAND,1
MP,EX,1,207E9
MP,DENS,1,7802.2
MP,PRXY,1,0
! (2) 定义节点和单元
LOCAL,11,,0.254
N,1
N,2,,0.00127
! 节点生成命令格式：NGEN, ITIME, INC, NODE1, NODE2, NINC, DX, DY, DZ, SPACE
NGEN,2,2,1,2,1,0.00127
E,1,3,4,2
CP,1,UX,1,2
M,1,UX
FINISH
! (3) 在求解模块中定义位移约束和模态求解选项后,开始求解
/SOLU
OUTPR,ALL,1
D,ALL,UZ,0
D,1,UY,0
MODE,0,1
MODOPT,REDUC
SOLVE
! (4) 提取计算结果
*GET,FREQ0,MODE,1,FREQ
FINISH
! (5) 重新进入求解模块,改变位移约束后,重新进行模态分析
/SOLU
OUTPR,ALL,1
DDELE,ALL
M,1,UX,,,UZ
D,1,UY
MODE,2,1
MXPAND,1,0,100
SOLVE
! (6) 提取计算结果
*GET,FREQ2,MODE,1,FREQ
! (7) 定义数组变量,将计算结果及其与理论解的比值输出到文本文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = '     f0,','     f2,'
LABEL(1,2) = ' Hz     ',' Hz     '
*VFILL,VALUE(1,1),DATA,3227.48,12.5
*VFILL,VALUE(1,2),DATA,FREQ0,FREQ2
*VFILL,VALUE(1,3),DATA,ABS(FREQ0/3227.48 ) ,ABS( FREQ2/12.5)
/COM
/OUT, EX9_7, out
/COM,-------------------  EX9.7  RESULTS COMPARISON --------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.1,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST, EX9_7, out