ex7.2.txt

通过实例详细介绍Ansys在实际工程中的应用

!7.2  悬索自由振动的频率
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,分析类型单元类型,实常数和材料参数
/FILENAME, EX7.2
/PREP7
/TITLE, EX7.2, VIBRATION OF A STRING UNDER TENSION
C***   VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND.,PAGE 264, ART. 8.2,
ANTYPE,STATIC
PSTRES,ON
ET,1,LINK1
R,1,1.97925E-6,0.54322E-2
MP,EX,1,207E9
MP,DENS,1,7727.4
! (2) 定义节点和单元
N,1
N,14,2.54
FILL
E,1,2
EGEN,13,1,1
! (3) 设置输出选项和位移约束
OUTPR,BASIC,1
D,ALL,ALL
FINISH
! (4) 在求解模块,求解预应力引起的应力状态
/SOLU
SOLVE
FINISH
! (5) 在后处理模块,定义单元表,提取单元的应力计算结果
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,13,ETAB,STRS
FINISH
! (6) 在时间历程后处理模块中,计算支座反力
/POST26
RFORCE,2,1,F,X
STORE
*GET,FORCE,VARI,2,EXTREM,VMAX
! (7) 再次进入求解模块,进行模态分析
/SOLU
ANTYPE,MODAL
MODOPT,SUBSP,3
MXPAND,3
PSTRES,ON
DDELE,2,UX,13
DDELE,2,UY,13
SOLVE
! (8) 获取前面3阶频率
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ
! (9) 定义数组变量,将计算结果存入文件
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = '      F,','      SI','      f1','      f2','      f3'
LABEL(1,2) = ' N     ','GMA,MPa ',', Hz    ',', Hz    ',', Hz    '
*VFILL,VALUE(1,1),DATA,2225.63, 1124.5,75.09,150.18,225.27
*VFILL,VALUE(1,2),DATA,ABS(FORCE),STRSS/1e6,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,ABS(FORCE/2225.63),ABS(STRSS/1124.5e6),ABS(FREQ1/75.09)
*VFILL,VALUE(4,3),DATA,ABS(FREQ2/150.18),ABS(FREQ3/225.27)
/COM
/OUT, EX7_2, out
/COM,-------------------  EX7.2 RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX7_2, out