ex10.5.txt

通过实例详细介绍Ansys在实际工程中的应用

!10.5  轴承支座的实体建模
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR,START
/FILENAME, EX10.5
/PREP7
/TITLE, EX10.5 SOLID MODEL OF AN AXIAL BEARING
/COM    ANY BASIC GEOMETRY TEXT
! (1)定义所有基本控制尺寸
B1=200
D1=100
H1=25
B2=100
D2=75
H2=50
D3=90
B3=50
D4=13
H3=H2/2
R1=12.5
! (2)生成底座部分矩形块和后部矩形块,右面支架和左面支架
! 利用指定两个对角位置(X1, X2, Y1, Y2, Z1, Z2)的矩形块命令BLOCK, 建立底座
BLOCK,-B1/2,B1/2,0,-H1,0,D1
BLOCK,-B2/2,B2/2,0,H2,0,D2
WPAVE,B2/2,0,0
BLOCK,0,B3,0,H2,0,D4
WPAVE,-B2/2,0,0
BLOCK,0,-B3,0,H2,0,D4
! (3) 定义半圆槽所在位置的轴, 通过体相减操作生成半圆槽
WPAVE,0,H2,0
! 使用圆柱体命令CYLIND,RAD1, RAD2, Z1, Z2, THETA1, THETA2 , 建立内半径为零, 外半径为D3/2, 从工作面开始到高度B2位置的360度实心圆柱体(中间的半圆槽实体)
CYLIND,0,D3/2,0,B2
VSBV,2,5
! (4) 移动工作面, 建立圆柱体, 通过减去圆柱体生成右支座和左支座上的孔
! 在右支座孔所在位置建立局部坐标系11和圆柱体, 通过减去圆柱的操作生成右支座上的孔
LOCAL,11,1,B2/2+(B1-B2)/4,H3
WPCSYS,1,11
CYLIND,0,R1,0,20
VSBV,3,2
! 在左支座孔所在位置建立局部坐标系12和圆柱体, 通过减去圆柱的操作生成左支座位置的孔
LOCAL,12,1,-B2/2-(B1-B2)/4,H3
WPCSYS,1,12
CYLIND,0,R1,0,20
VSBV,4,2
! (5) 定义底面上的支承孔
! 在底面上移动工作面到右边底孔位置, 建立圆柱体, 通过减去体操作生成右底孔
CSYS,0
WPAVE,B2/2+(B1-B2)/4,,D1*0.75
WPROTA,,90
CYLIND,0,R1,0,30
VSBV,1,2
! 在底面上移动工作面到左边底孔位置, 建立圆柱体, 通过减去体操作生成左底孔
WPOFFS,-B2-(B1-B2)/2
CYLIND,0,R1,0,30
VSBV,4,1
! (6) 生成右支座和左支座的倒圆
! 在极坐标系下, 建立右支座倒圆位置的圆柱形曲面, 通过体减去面的操作截开体, 删除多余部分以生成右支座的倒圆
CSYS,11
K,100,(B1-B2)/4,0,0
K,101,(B1-B2)/4,90,0
K,102,(B1-B2)/4,90,20
K,103,(B1-B2)/4,0,20
A,100,101,102,103
VSBA,5,3,SEPO
VDELE,1,,,1
!  在极坐标系下, 建立左支座倒圆位置的圆柱形曲面, 通过体减去面命令VSBA(Volume SuBtract Area)截开体, 删除多余部分以生成左支座的倒圆
CSYS,12
K,105,(B1-B2)/4,180,0
K,106,(B1-B2)/4,90,0
K,107,(B1-B2)/4,90,20
K,108,(B1-B2)/4,180,20
A,105,106,107,108
VSBA,3,3,SEPO
VDELE,1,,,1
! (7) 将所有体通过粘接(GLUE)联结为一个整体
VGLUE,ALL
! (8) 切换显示模式, 显示生成体的情况
/TYPE,1,4
/VIEW,1,1,2,3
/AUTO,1
/TRIAD,OFF
VPLOT
! (9) 计算总体积, 存入变量并显示所有变量的值
VSUM
*GET,TVOL,VOLU,,VOLU
*status,parm
! (10) 将体积计算结果存入结果文件, 并显示这个文件的内容
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,1,2
LABEL(1,1) = 'VOLUME '
LABEL(1,2) = 'NO UNTS '
*VFILL,VALUE(1,1),DATA,657557
*VFILL,VALUE(1,2),DATA,TVOL
*VFILL,VALUE(1,3),DATA,ABS(TVOL/657557)
/COM
/OUT, EX10_5,out
/COM,------------------- EX10.5  RESULTS COMPARISON--------------
/COM,
/COM,                  |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F8.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,EX10_5, out