ex8.4.txt

通过实例详细介绍Ansys在实际工程中的应用

!8.4  用壳体单元计算悬臂等强度梁的自由振动
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,分析类型,单元类型,实常数和材料参数
/FileName, EX8.4
/PREP7
SMRT,OFF
/TITLE, EX8.4, VIBRATION OF A WEDGE
C***    VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 392, ART. 62
C***          USING SHELL63 ELEMENTS WITH BENDING STIFFNESS Option
ANTYPE,MODAL
MXPAND,1
MODOPT,REDUC,2,,,2
ET,1, SHELL63,2
R,1, 25.4E-3
MP,EX,1, 207E9
MP,DENS,1, 7781
MP,NUXY,1,0
! (2) 通过关键点定义线,通过关键点定义面,对面进行面单元划分得到有限元模型
K,1
K,2, 406.4E-3
K,3, 406.4E-3,50.8E-3
L,2,3
LESIZE,1,,,1
A,1,2,3,3
ARSYM,Y,1
NUMMRG,KP
ESIZE,,4
AMESH,1,2
! (3) 选择某些位置的节点,施加边界条件,并指定输出选项
/PNUM, NODE, 1
NSEL,S,LOC,Y,0
M,ALL,UZ
NSEL,S,LOC,X, 406.4E-3
D,ALL,UZ,,,,,ROTX,ROTY,UX,UY
NSEL,ALL
OUTPR,ALL,1
OUTRES,ALL,0
FINISH
! (4) 进入求解模块,开始求解并提取频率计算结果
/SOLU
SOLVE
*GET,FREQ1,MODE,1,FREQ
FINISH
! (5) 重新进入前处理模块,定义使用带壳体效应的壳单元
/PREP7
SMRT,OFF
C***      USING SHELL63 ELEMENTS WITH SHELL OPTION
ET,1,SHELL63
FINISH
! (6) 用壳体单元重新计算
/SOLU
SOLVE
*GET,FREQ2,MODE,1,FREQ
! (7) 定义数组变量,将计算结果输出到文本文件
*DIM,LABEL,CHAR,1,2
*DIM,VALUE_1,,1,3
*DIM,VALUE_2,,1,3
LABEL(1,1) = '      f,'
LABEL(1,2) = ' Hz     '
*VFILL,VALUE_1(1,1),DATA,259.243
*VFILL,VALUE_1(1,2),DATA,FREQ1
*VFILL,VALUE_1(1,3),DATA,ABS(FREQ1/259.243 )
*VFILL,VALUE_2(1,1),DATA,259.243
*VFILL,VALUE_2(1,2),DATA,FREQ2
*VFILL,VALUE_2(1,3),DATA,ABS(FREQ2/259.243 )
/COM
/OUT, EX8_4, out
/COM,-------------------  EX8.4 RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,RESULTS USING PLATE ELEMENTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,
/COM,RESULTS USING SHELL ELEMENTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST, EX8_4, out