ex8.2.txt

通过实例详细介绍Ansys在实际工程中的应用

!8.2  自由-自由梁的纵向自由振动
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,单元类型,材料参数和实常数
/FileName, EX8.2
/PREP7
/TITLE, EX8.2, LONGITUDINAL VIBRATION OF A FREE-FREE ROD
C***VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND, PAGE 269, EX 8.3-1
ANTYPE,MODAL
ET,1,BEAM3
R,1,1,1,1
MODOPT,LANB,3
MP,EX,1,207E9
MP,DENS,1,7802
MP,PRXY,,0.3
! (2) 通过关键点的定义建立模型
K,1
K,2,20.32
L,1,2
ESIZE,,11
LMESH,1
OUTPR,BASIC,1
D,ALL,UY,,,,,ROTZ
FINISH
! (3) 在求解模块,开始模态分析的求解
/SOLU
SOLVE
FINISH
! (4) 在一般后处理模块中,获取频率计算结果
/POST1
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ
! (5) 定义数组变量,将计算结果输出到文本文件
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = '      f1','      f2','      f3'
LABEL(1,2) = ',  (Hz) ',',  (Hz) ',',  (Hz) '
*VFILL,VALUE(1,1),DATA,0,126.70,253.40
*VFILL,VALUE(1,2),DATA,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,0,ABS(FREQ2/126.70),ABS(FREQ3/253.40)
/COM
/OUT,EX8_2, out
/COM,------------------- EX8.2 RESULTS COMPARISON --------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,EX8_2, out