ex8.1b.txt

通过实例详细介绍Ansys在实际工程中的应用

!8.1  简支梁的自振频率计算(增加节点后的情况)
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,单元类型,材料参数和实常数
/FileName, EX8.1B
/PREP7
/TITLE, EX8.1B, FUNDAMENTAL FREQUENCY OF A SIMPLY SUPPORTED BEAM
C*** VIBRATION THEORY AND APPLICATIONS, THOMSON, 2ND, PAGE 18, EX 1.5-1
ET,1,BEAM3
MP,EX,1,207E9
MP,DENS,1,7781
MP,GXY,1,207E9/2.6
R,1,25.81e-4,55.493e-8,50.8e-3
! (2) 通过关键点的定义建立模型
K,1
K,2,2.032
L,1,2
LESIZE,ALL,,,14
LMESH,1
/PNUM, NODE, 1
EPLOT
FINISH
! (3) 在求解模块定义模态分析选项,施加位移约束后开始模态分析的求解
/SOLU
ANTYPE,MODAL
MODOPT,REDUC,3,,,3
MXPAND,3
M,3,UY,15
OUTPR,ALL,1
DK,ALL,UX
DK,ALL,UY
! (4) 在求解模块定义模态分析选项,施加位移约束后开始模态分析的求解
PSOLVE,ELFORM
PSOLVE,TRIANG
PSOLVE,EIGREDUC
PSOLVE,EIGEXP
FINISH
! (5) 在时间历程后处理器获取频率计算结果
/POST26
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ
! (6) 进入一般后处理模块/POST1,图形显示振型
/POST1
set,1,1
PLDISP,2
set,1,2
PLDISP,2
set,1,3
PLDISP,2
! (7) 定义数组变量,将计算结果输出到文本文件
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = '      f1', '      f2', '      f3',
LABEL(1,2) = ', (Hz)  ', ', (Hz)   ', ', (Hz)  '
*VFILL,VALUE(1,1),DATA,28.771,115.086,258.943
*VFILL,VALUE(1,2),DATA,FREQ1, FREQ2, FREQ3
*VFILL,VALUE(1,3),DATA,ABS(FREQ1/28.771) ,ABS(FREQ2/115.086) ,ABS(FREQ3/258.932)
/COM
/OUT,EX8_1_1, out
/COM,------------------- EX8.1(1) RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,EX8_1_1, out