ex5.3.txt

通过实例详细介绍Ansys在实际工程中的应用

!5.3  柱形容器在内压作用下的静力分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)定义工程选项,单元类型,实常数和材料参数
/FileName, EX5.3
/PREP7
/TITLE, EX5.3, CYLINDRICAL SHELL UNDER INTERNAL PRESSURE
C***   STR. OF MATL., TIMOSHENKO, PART 1, 3RD ED., PAGE 45, ART. 11
C***   AND UGURAL AND FENSTER, ADV. STRENGTH AND APPL. ELAS., 1981
ANTYPE,STATIC
ET,1,SHELL51
R,1,25.4
MP,EX,1,207E3
MP,NUXY,1,0.3
! (2)定义节点和单元
N,1,1524
N,2,1524,254
E,1,2
! (3)定义耦合自由度,位移约束和荷载力
CP,1,UX,1,2
D,1,UY,,,,,UZ,ROTZ
D,2,ROTZ
F,2,FY, 25155716
SFE,1,1,PRES,,3.4476
FINISH
! (4)在求解模块中，设置输出选项后求解
/SOLU
OUTPR,ALL,1
SOLVE
FINISH
! (5)在后处理模块定义单元表,提取单元应力
/POST1
ETABLE,STRS_Y,NMISC,7
ETABLE,STRS_Z,NMISC,6
*GET,STRSS_Y,ELEM,1,ETAB,STRS_Y
*GET,STRSS_Z,ELEM,1,ETAB,STRS_Z
! (6)定义数组变量,将计算结果通过它们保存到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'STRESS,Y ','STRESS,Z'
LABEL(1,2) = ' (MPa)  ',' (MPa)  '
*VFILL,VALUE(1,1),DATA,103.43,206.86
*VFILL,VALUE(1,2),DATA,STRSS_Y,STRSS_Z
*VFILL,VALUE(1,3),DATA,ABS(STRSS_Y/103.43),ABS(STRSS_Z/206.86)
/COM
/OUT, EX5_3, out
/COM,-------------------  EX5.3 RESULTS COMPARISON ---------------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST, EX5_3, out