ex5.1.txt

通过实例详细介绍Ansys在实际工程中的应用

!5.1  含椭圆孔的椭圆薄膜在外部张力作用下的静力分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年7月）
FINISH
/CLEAR, NOSTART
! (1) 设置工程选项,分析类型,单元类型和材料参数
/FileName, EX5.1
/PREP7
SMRT,OFF
/TITLE, EX5.1, ELLIPTIC MEMBRANE UNDER A UNIFORMLY-DISTRIBUTED LOAD(PLANE42)
/COM,   NAFEMS (REF.58), TEST NO. LE1 (MODIFIED)
/COM,   USING 2-D STRUCTURAL SOLID, PLANE42
ANTYPE,STATIC
ET,1,PLANE42,,,3
MP,EX,1,210E9
MP,NUXY,1,0.3
R,1,0.1
! (2) 在椭圆坐标系下,定义关键点,线和面
! LOCAL, KCN, KCS, XC, YC, ZC, THXY, THYZ, THZX, PAR1, PAR2
LOCAL,11,1,,,,,,,0.5
K,1,2,90
K,2,2,0
L,1,2
LOCAL,12,1,,,,,,,0.8461585
K,3,3.25,90
K,4,3.25,0
L,3,4
CSYS,0
L,2,4
L,1,3
AL,2,4,1,3
! (3)在相应的线上施加位移约束
DL,4,1,SYMM
DL,3,1,SYMM
SFL,2,PRES,-10E6
MSHK,2
MSHA,0,2D
SAVE
FINISH
! (4)执行自适应网格划分和求解宏程序,执行自定义的后处理宏程序
ADAPT,3,7,,,1
/Post1
EPLOT
PLDISP,1
PLNSOL,S,X
PLNSOL,S,Y
PLNSOL,S,1
FINISH
! (5)定义完成后处理功能的宏程序MAC
*CREATE,MAC
/Graphics,Full
/POST1
PRERR
NSEL,S,LOC,Y,0.0
NSEL,R,LOC,X,2.0
*GET,MNODE,NODE,,NUM,MAX
*GET,SY_D,NODE,MNODE,S,Y
NSEL,ALL
ESEL,ALL
*status,parm
/Graphics,Power
*END   
! (6)用前定义的宏程序完成后处理,将计算结果保存到变量
*USE,MAC
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'TAN STR '
LABEL(1,2) = 'MPa'
*VFILL,VALUE(1,1),DATA,92.70
*VFILL,VALUE(1,2),DATA,(SY_D/1000000)
*VFILL,VALUE(1,3),DATA,ABS((SY_D/1000000)/92.7)
SAVE, TABLE1
FINISH
! (7)改变单元为PLANE82,重新计算
/CLEAR, NOSTART
/COM,    USING 2-D 8-NODE STRUCTURAL SOLID, PLANE82
/FileName, EX5.1
/PREP7
SMRT,OFF
RESUME
/TITLE, EX5.1, ELLIPTIC MEMBRANE UNDER A UNIFORMLY-DISTRIBUTED LOAD(PLANE82)
ET,1,PLANE82,,,3
FINISH
! (8) 执行自适应网格宏程序,执行自定义的后处理宏程序
ADAPT,2,5,,,1
/Post1
/WINDOW,5,OFF
/WINDOW,1,FULL
PLNSOL,S,EQV
PLDISP,1
PLNSOL,S,X
PLNSOL,S,Y
PLNSOL,S,1
FINISH
! (9) 用前定义的宏程序完成后处理,将计算结果保存到变量
*USE,MAC
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'TAN STR '
LABEL(1,2) = 'MPa'
*VFILL,VALUE(1,1),DATA,92.70
*VFILL,VALUE(1,2),DATA,(SY_D/1000000)
*VFILL,VALUE(1,3),DATA,ABS((SY_D/1000000)/92.7)
SAVE, TABLE2
! (10)从数据库中恢复数据,将两种不同单元的计算结果通过数组变量保存到文件
RESUME,TABLE1
/COM
/OUT, EX5_1, out
/COM,-------------------  EX5.1 RESULTS COMPARISON --------------
/COM,
/COM,                  |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,PLANE42 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F8.3)
/NOPR
RESUME,TABLE2
/GOPR
/COM,
/COM,PLANE82 RESULTS:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F8.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST, EX5_1, out