ex4.8.txt

通过实例详细介绍Ansys在实际工程中的应用

!4.8  均匀拉力作用下含圆孔板的孔边应力集中
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)设置工程选项,分析类型,单元类型和材料参数
/FileName,EX4.8
/PREP7
smrt,off
/TITLE, EX4.8, STRESS CONCENTRATION AT A HOLE IN A PLATE with PLANE2.
C*** ROARK 4TH EDITION, PAGE 384.
/NOPR
ANTYPE,STATIC
ET,1,PLANE2
MP,EX,1,207E3
MP,NUXY,1,0.3
! (2)定义关键点
K,1,152.4
K,2,152.4,152.4
K,3,,152.4
K,4,,12.7
K,5,12.7
K,6
! (3)定义线和线单元划分的尺寸
L,1,2
L,2,3
L,3,4
LESIZE,3,,,4,.25
LARC,4,5,6,12.7
LESIZE,4,,,6
L,5,1
LESIZE,5,,,4,4
! (4)定义面并将其划分为面单元,图形显示单元布置
AL,1,2,3,4,5
ESIZE,,4
AMESH,ALL
/AUTO,1
/PLOPTS,INFO,0
/PLOPTS,WINS,0
/WINDOW,,LTOP
EPLOT
! (5)选择相应的线,施加位移和荷载边界条件
LSEL,S,LINE,,3,5,2
DL,ALL,,SYMM
LSEL,S,LINE,,1
NSLL,,1
SF,ALL,PRES,-6.895
LSEL,ALL
NSEL,ALL
CSYS,1
FINISH
! (6)进入求解模块求解
/SOLU
SOLVE
SAVE
FINISH
! (7)进入后处理,显示计算结果
/POST1
SET,1,1
NSORT,S,X,,,3
PRNSOL,S,COMP
/WINDOW,1,OFF
/NOERASE
/DSCALE,2,1
/WINDOW,2,RTOP
PLNSOL,S,X
PLNSOL,S,Y
*GET,CRSESTR,NODE,18,S,X
*status,parm
! (8)定义数组,将计算结果保存到数组,然后保存到数据库文件TABLE_1
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'MX STR '
LABEL(1,2) = 'CRS MODEL'
*VFILL,VALUE(1,1),DATA,20.81
*VFILL,VALUE(1,2),DATA,CRSESTR
*VFILL,VALUE(1,3),DATA,ABS(CRSESTR/20.81)
SAVE, TABLE_1
! (9)改变单元类型为PLANE42,用子模型技术重新计算
FINISH
/CLEAR, NOSTART
/FILNAME,4.8SUBM1
/PREP7
smrt,off
/NOPR
/TITLE, EX4.8, STRESS CONCENTRATION AT A HOLE IN A PLATE With PLANE42 SUB-MODEL
C*** BOUNDARY INTERPOLATION, MODIFIED SECTION
ANTYPE,STATIC
ET,1,PLANE42
MP,EX,1,207E3
MP,NUXY,1,0.3
! (10)在柱坐标系下定义孔边子模型上的关键点
CSYS,1
K,10,12.7,45
K,11,12.7,90
K,12,38.1,45
K,13,38.1,90
A,10,12,13,11
ESIZE,,8
MSHK,1
MSHA,0,2D
AMESH,1
! (11)设置窗口选项后,绘制单元布置
/WINDOW,2,OFF
/ERASE
/PLOPTS,INFO,0
/PLOPTS,WINS,0
/WINDOW,,LTOP
/USER
/DIST,1,18
/FOCUS,1,14,25
EPLOT
LSEL,S,LINE,,1,2
NSLL,,1
NWRITE
LSEL,ALL
NSEL,ALL
FINISH
SAVE
! (12)在后处理模块恢复模型数据,读入计算结果
/POST1
RESUME, EX4.8,db
FILE, EX4.8,rst
CBDOF,,,,,,,0,,0
! (13)重新读模型,施加不同的边界条件
FINISH
/PREP7
smrt,off
RESUME
/NOPR
/INPUT,,cbdo,,:cb1
/GOPR
LSEL,S,LINE,,3
DL,ALL,,SYMM
FINISH
! (14)进入求解模块求解
/SOLU
SOLVE
FINISH
! (15)在后处理模块显示应力计算结果,
/POST1
SET,1,1
NSORT,S,X,,,3
PRNSOL,S,COMP
/WINDOW,1,OFF
/AUTO,3
/WINDOW,3,BOT
/NOERASE
/PLOPTS,MINM,1
/USER,3
/DIST,3,5.08
/FOCUS,3,5.08,12.7
/CONTOUR,3,,AUTO
PLNSOL,SX
*GET,SUBSTR,NODE,18,S,X
! (16) 定义数组,将计算结果保存到数组,然后保存到数据库文件TABLE_2
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'MAX STRS'
LABEL(1,2) = ' SUBMOD'
*VFILL,VALUE(1,1),DATA,20.81
*VFILL,VALUE(1,2),DATA,SUBSTR
*VFILL,VALUE(1,3),DATA,ABS(SUBSTR/20.81 )
SAVE, TABLE_2
! (17) 改变单元类型为PLANE146,重新计算
FINISH
/CLEAR,NOSTART
/FILNAME,4.8SUBM1
/PREP7
smrt,off
/TITLE, EX4.8, STRESS CONCENTRATION AT A HOLE IN A PLATE With PLANE146 Element
C*** ROARK 4TH EDITION, PAGE 384.
/NOPR
ANTYPE,STATIC
ET,1,PLANE146
MP,EX,1,207E3
MP,NUXY,1,0.3
! (18)定义关键点
K,1,152.4
K,2,152.4,152.4
K,3,,152.4
K,4,,12.7
K,5,12.7
K,6
! (19)定义线和单元划分的段数
L,1,2
L,2,3
L,3,4
LESIZE,3,,,4,.25
LARC,4,5,6,12.7
LESIZE,4,,,6
L,5,1
LESIZE,5,,,4,4
! (20) 定义面并将其划分为面单元,图形显示单元布置
AL,1,2,3,4,5
ESIZE,,4
AMESH,ALL
/AUTO,1
/PLOPTS,INFO,0
/PLOPTS,WINS,0
/WINDOW,,LTOP
EPLOT
! (21) 选择相应的线,施加位移和荷载边界条件
LSEL,S,LINE,,3,5,2
DL,ALL,,SYMM
LSEL,S,LINE,,1
NSLL,,1
SF,ALL,PRES,-6.895
LSEL,ALL
NSEL,ALL
CSYS,1
FINISH
! (22) 进入求解模块求解
/SOLU
SOLVE
FINISH
! (23) 进入后处理,显示计算结果
/POST1
SET,1,1
/WINDOW,1,OFF
/NOERASE
/DSCALE,2,1
/WINDOW,2,RTOP
PLNSOL,S,X
*GET,SUBSTR,NODE,18,S,X
! (24) 定义数组,将结果数据保存到这些数组,然后存入数据库TABLE_3
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'MAX STRS'
LABEL(1,2) = 'CRS MOD '
*VFILL,VALUE(1,1),DATA,20.81
*VFILL,VALUE(1,2),DATA,SUBSTR
*VFILL,VALUE(1,3),DATA,ABS(SUBSTR/20.81 )
SAVE,TABLE_3
FINISH
! (25) 从各个数据库中恢复数据,依次输出到文件
RESUME,TABLE_1
/OUT, EX4_8, out
/COM,-------------------  EX4.8 RESULTS COMPARISON---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,PLANE2
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,PLANE42
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM,PLANE146
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
*LIST, EX4_8, out
! (26) 删除中间数据文件
/DEL,4.8SUBM1,cbdo
/DEL,4.8SUBM1,db
/DEL,4.8SUBM1,emat
/DEL,4.8SUBM1,esav
/DEL,4.8SUBM1,node
/DEL,TABLE_1
/DEL,TABLE_2
/DEL,TABLE_3