ex4.4.txt

通过实例详细介绍Ansys在实际工程中的应用

!4.4  用二维实体单元分析等截面悬臂梁的平面弯曲
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)设置工程选项，单元类型和材料参数
/FileName,EX4.4
/PREP7
/TITLE, EX4.4, BENDING OF A SOLID BEAM (PLANE ELEMENTS)
C***     FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED.,PG. 104,106
ANTYPE,STATIC
ET,1,PLANE42,,,3,,,2
MP,EX,1,207E3
MP,NUXY,1,0.0
R,1,25.4
! (2)定义节点
N,1
N,6,254
FILL
! NGEN, ITIME, INC, NODE1, NODE2, NINC, DX, DY, DZ, SPACE
NGEN,2,10,1,6,1,,50.8
E,1,2,12,11
EGEN,5,1,1
! (3)施加第1种情况的边界条件:端部力偶作用情况
/COM, EX4.4, CASE 1 - END MOMENT, ROARK, PAGE 106, NO. 9
D,1,ALL,,,11,10
F,6,FX,4448.3
F,16,FX,-4448.3
OUTPR,NSOL,1
OUTPR,ESOL,1
FINISH
! (4)进入求解模块求解
/SOLU
SOLVE
FINISH
! (5)在后处理模块,提取节点位移计算结果
/POST1
*GET,U1,NODE,16,U,Y
PLNSOL,S,X
FINISH
! (6)改变荷载为第二种荷载工况:端部力作用情况，重新计算
/SOLU
/COM, EX16, CASE 2 - END LOAD, ROARK, PAGE 104, NO.1
F,6,FX,,,16,10
F,6,FY,667.25,,16,10
SOLVE
FINISH
! (7) 在后处理模块,提取节点位移计算结果
/POST1
*GET,U2,NODE,16,U,Y
PLNSOL,S,X
! (8) 定义数组变量，将计算结果通过数组变量输出到文件
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
*DIM,VALUE2,,1,3
LABEL(1,1) = 'DEFL'
LABEL(1,2) = ' (mm)  '
*VFILL,VALUE(1,1),DATA,0.127
*VFILL,VALUE(1,2),DATA,U1
*VFILL,VALUE(1,3),DATA,ABS(U1/0.127)
SAVE, TABLE_1
*VFILL,VALUE2(1,1),DATA,0.127
*VFILL,VALUE2(1,2),DATA,U2
*VFILL,VALUE2(1,3),DATA,ABS(U2/0.127)
SAVE, TABLE_2
RESUME,TABLE_1
/COM
/OUT, EX4_4, out
/COM,-------------------  EX4.4 RESULTS COMPARISON ---------------------
/COM,
/COM,CASE 1:          |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.5,'  ',F10.5,'   ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,CASE 2:
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A8,A8,'   ',F10.5,'  ',F10.5,'   ',1F5.3)
/COM,-----------------------------------------------------------------
/COM,
/COM,-----------------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST, EX4_4, out