ex4.7.txt

通过实例详细介绍Ansys在实际工程中的应用

!4.7  端部集中力作用的悬臂圆环曲梁平面弯曲的三维分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)定义工程选项,分析类型,单元类型和材料参数
/FileName,EX4.7
/PREP7
smrt,off
/TITLE, EX4.7, BENDING OF A CURVED BEAM WITH SOLID5
C***  FORMULAS FOR STRESS AND STRAIN, ROARK, 4TH ED.
ANTYPE,STATIC
ET,1,SOLID5,2
MP,EX,1,70E3
MP,NUXY,1,0.25
! (2)在柱坐标系定义关键点,线和体
CSYS,1
K,1,104.6
K,2,109.7
KGEN,2,1,2,1,,,2.54
KGEN,2,1,4,1,,90
L,1,5
LESIZE,1,,,20
V,1,2,4,3,5,6,8,7
ESIZE,,1
/VIEW,1,1,1,1
/Device,VECTOR,1
VMESH,1
! (3)选择节点, 施加位移约束和荷载
/Device,VECTOR,0
NSEL,S,LOC,Y,0
D,ALL,ALL,0
NSEL,ALL
FK,5,FY,1.1121
*REPEAT,4,1
NOORDER
FINISH
! (4)进入求解模块, 开始求解
/SOLU
SOLVE
FINISH
! (5)定义完成后处理的宏程序
*CREATE,MAC
/POST1
CSYS,0
NSEL,S,LOC,X,0,0.01,,1
PRNSOL,U,COMP
LCDEF,1,1
LCFACT,1,(1/2.187)
LCASE,1
PRNSOL,U,COMP
FINISH
*END
! (6)提取自由端位移计算结果
/POST1
*GET,U1,NODE,5,U,Y
PLNSOL,S,Y
! (7)定义数组, 并将计算结果保存到数组, 供结果输出
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'mm'
*VFILL,VALUE(1,1),DATA,2.187
*VFILL,VALUE(1,2),DATA,U1
*VFILL,VALUE(1,3),DATA,ABS(U1/2.187)
SAVE, TABLE_1
*USE,MAC
! (8)重新开始用SOLID92单元分析
FINISH
/CLEAR, NOSTART
/FileName,EX4.7
/PREP7
smrt,off
/TITLE, EX4.7, BENDING OF A CURVED BEAM WITH SOLID92
ET,1,SOLID92
MP,EX,1,70E3
MP,NUXY,1,0.25
! (9)通过关键点定义模型
CSYS,1
/VIEW,1,1,1,1
K,1,104.6
K,2,109.7
KGEN,2,1,2,1,,,2.54
KGEN,2,1,4,1,,4.5
V,1,2,4,3,5,6,8,7
! VGEN, ITIME, NV1, NV2, NINC, DX, DY, DZ, KINC, NOELEM, IMOVE
VGEN,20,1,1,1,,4.5,,4
ESIZE,,1
VMESH,ALL
! (10)选择节点, 施加位移约束和荷载
NSEL,S,LOC,Y,0
D,ALL,ALL,0
NSEL,S,LOC,Y,90
CP,1,UY,ALL
NSEL,R,LOC,X,109.7
NSEL,R,LOC,Z,0
F,ALL,FY,4.4483
NSEL,ALL
SAVE
FINISH
! (11)进入求解模块开始求解, 并使用前面的宏程序进行相应的后处理
/SOLU
SOLVE
FINISH
! (12)选择自由端节点, 提取位移计算结果
/POST1
PLNSOL,S,Y
*USE,MAC
NDE=NODE(0,109.7,0)
*GET,UY2,NODE,NDE,U,Y
*SET,U2,(UY2/(1/2.187))
*status,parm
! (13)定义数组, 并将计算结果保存到数组, 供结果输出
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'mm'
*VFILL,VALUE(1,1),DATA,2.187
*VFILL,VALUE(1,2),DATA,U2
*VFILL,VALUE(1,3),DATA,ABS(U2/2.187)
SAVE, TABLE_2
! (14)重新开始用SOLID98单元分析
/PREP7
smrt,off
RESUME
/TITLE, EX4.7, BENDING OF A CURVED BEAM WITH SOLID98
ET,1,SOLID98,2
FINISH
! (15)进入求解模块开始求解, 并使用前面的宏程序进行相应的后处理
/SOLU
SOLVE
FINISH
! (16)选择自由端节点, 提取位移计算结果
/POST1
PLNSOL,S,Y
*USE,MAC
NDE=NODE(0,109.7,0)
*GET,UY3,NODE,NDE,U,Y
*SET,U3,(UY3/(1/2.187))
*status,parm
! (17)定义数组, 并将计算结果保存到数组, 供结果输出
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'mm'
*VFILL,VALUE(1,1),DATA,2.187
*VFILL,VALUE(1,2),DATA,U3
*VFILL,VALUE(1,3),DATA,ABS(U3/2.187)
SAVE, TABLE_3
! (18)重新开始用SOLID148单元分析
/PREP7
smrt,off
RESUME
/TITLE, EX4.7, BENDING OF A CURVED BEAM WITH SOLID148
ET,1,SOLID148,2
FINISH
! (19)进入求解模块开始求解
/SOLU
SOLVE
FINISH
! (20)图形显示环向应力分布,使用前面的宏程序进行后处理, 选择自由端节点, 提取位移计算结果
/POST1
SET,LAST
PLNSOL,S,Y
*USE,MAC
NDE=NODE(0,109.7,0)
*GET,UY3,NODE,NDE,U,Y
*SET,U3,(UY3/(1/2.187))
*status,parm
! (21)定义数组, 并将计算结果保存到数组, 供结果输出
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'DEFL '
LABEL(1,2) = 'mm'
*VFILL,VALUE(1,1),DATA,2.187
*VFILL,VALUE(1,2),DATA,U3
*VFILL,VALUE(1,3),DATA,ABS(U3/2.187)
SAVE, TABLE_4
! (22)从各个数据库中恢复数据, 并将计算结果输出到文件EX4_7.out
RESUME,TABLE_1
/COM
/OUT, EX4_7, out
/COM,-------------------  EX4.7 RESULTS COMPARISON ------------
/COM,
/COM,                      TARGET   |    ANSYS   |    RATIO
/COM, SOLID5
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.3,'  ',F11.3,'   ',1F6.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM, SOLID92
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.3,'  ',F11.3,'   ',1F6.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM, SOLID98
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.3,'  ',F11.3,'   ',1F6.3)
/NOPR
RESUME,TABLE_4
/GOPR
/COM,
/COM, SOLID148
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.3,'  ',F11.3,'   ',1F6.3)
/COM,---------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
/DELETE,TABLE_4
/DELETE,MAC
*LIST, EX4_7, out