ex4.3.txt

来自「通过实例详细介绍Ansys在实际工程中的应用」· 文本 代码 · 共 95 行

!4.3  用实体单元分析变截面杆的拉伸
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)设置工程选项,定义分析类型,单元类型和材料参数
/FileName,EX4.3
/PREP7
smrt,off
/TITLE, EX4.3, ELONGATION OF A SOLID BAR WITH VARIED SECTION
/COM    INTROD. TO STRESS ANALYSIS, HARRIS, 1ST ED., PAGE 237, PROB. 4
ANTYPE,STATIC
ET,1,SOLID45
MP,EX,1,70.71E3
MP,NUXY,1,0.3
! (2)定义固定端4个点和自由端4个点，过这8个点定义体，对体划分单元
/VIEW,1,1,1,1
K,1,25.4,,25.4
K,2,-25.4,,25.4
K,3,-25.4,,-25.4
K,4,25.4,,-25.4
K,5,12.7,254,12.7
K,6,-12.7,254,12.7
K,7,-12.7,254,-12.7
K,8,12.7,254,-12.7
V,1,2,3,4,5,6,7,8
LSEL,S,LINE,,5,11,2
LESIZE,ALL,,,7
LSEL,ALL
ESIZE,,1
/OUT,SCRATCH
VMESH,1
/OUT
! (3)施加位移约束和荷载
OUTPR,BASIC,ALL
NSEL,S,LOC,Y,0
D,ALL,ALL
NSEL,ALL
NSEL,S,LOC,Y,254
SF,,PRES,-68.949
NSEL,ALL
FINISH
! (4)在求解模块，开始静力分析的求解
/SOLU
SOLVE
FINISH
! (5)在后处理模块中，显示Y方向应力云图
/POST1
ETABLE,SIGY,S,Y
/VIEW,1,1
/VUP,1,-Y
NSLE,S
PLNSOL,S,Y
ESEL,S,ELEM,,4
PRETAB,SIGY
PRNSOL,S,COMP
ESEL,ALL
NSEL,S,LOC,Y,254
PRNSOL,DOF
NSEL,ALL
! (6)选择指定位置的节点和单元，并提取它们的位移和应力
/NOPR
MID_NODE = NODE(0,128,0)
MID_ELM = ENEARN(MID_NODE)
BOT_NODE = NODE (0,254,0)
*GET,DEF,NODE,BOT_NODE,U,Y
*GET,STRSS,ELEM,MID_ELM,ETAB,SIGY
! (7)定义数组变量，将计算结果通过数组变量输出到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'MAX DEF ','SIGY MID'
LABEL(1,2) = '(mm)    ','_ELM MPa'
*VFILL,VALUE_C1(1,1),DATA,0.12384,30.644
*VFILL,VALUE_C1(1,2),DATA,DEF,STRSS
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF/0.12384) ,ABS(STRSS/30.644)
/GOPR
FINISH
/COM
/OUT, EX4_3, out
/COM,-------------------  EX4.3 RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,RESULTS FOR SOLID45:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,'   ',F12.7,'  ',F12.7,'   ',1F5.3)
/NOPR
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX4_3, out
/DELETE,SCRATCH
FINISH