ex4.5.txt

通过实例详细介绍Ansys在实际工程中的应用

!4.5  变截面悬臂梁在端部集中力作用下的平面静力分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)设置工程选项，定义分析类型，单元类型
/FileName,EX4.5
/PREP7
/TITLE, EX4.5, LATERALLY LOADED TAPERED SUPPORT STRUCTURE (QUAD. ELEMENTS)
C***     MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 342, PROB. 7.18
C***          使用 PLANE42 单元
ANTYPE,STATIC
ET,1,PLANE42,,,3,,,2        结果
R,1,50.8
MP,EX,1,207E3
MP,NUXY,1,0.0
! (2)定义节点位置和单元连接
N,1,635
N,7,1905
FILL
N,8,635,-76.2
N,14,1905,-228.6
FILL
E,2,1,8,9
EGEN,6,1,1
! (3)选择节点，施加位移边界条件和荷载
NSEL,S,LOC,X,1905
D,ALL,ALL
NSEL,ALL
F,1,FY,-17793
FINISH
! (4)在求解模块，开始求解
/SOLU
OUTPR,,1
SOLVE
FINISH
! (5)提取指定位置节点的应力，绘制变形图
/POST1
END_NODE = NODE (1905,0,0)
*GET,STS_E_42,NODE,END_NODE,S,X
PLDISP,2
MID_NODE = NODE (1270,0,0)
*GET,STS_M_42,NODE,MID_NODE,S,EQV
PLNSOL,S,X
PLNSOL,S,1
PLNSOL,S,3
FINISH
! (6)改用更高阶的平面应力单元PLANE82重新计算
/PREP7
/TITLE, EX4.5, LATERALLY LOADED TAPERED SUPPORT STRUCTURE (QUAD. ELEMENTS)
C***     MECHANICS OF SOLIDS, CRANDALL AND DAHL, 1959, PAGE 342, PROB. 7.18
ET,1,PLANE82,,,3,,,2
EMID
NSEL,R,LOC,X,1905
NSEL,R,LOC,Y,-114.3
D,ALL,ALL
NSEL,ALL
FINISH
! (7)在求解模块求解
/SOLU
SOLVE
FINISH
! (8)提取指定位置的节点的应力计算结果
/POST1
END_NODE = NODE (1905,0,0)
*GET,STS_E_82,NODE,END_NODE,S,X
MID_NODE = NODE (1270,0,0)
*GET,STS_M_82,NODE,MID_NODE,S,EQV
PLNSOL,S,X
PLNSOL,S,1
PLNSOL,S,3
! (9) 定义数组变量，将计算结果通过数组变量输出到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUEI,,2,3
*DIM,VALUEII,,2,3
LABEL(1,1) = 'MID_STRS','END-STRS'
LABEL(1,2) = ' (MPa)  ',' (MPa)  '
*VFILL,VALUEI(1,1),DATA,57.457,51.073
*VFILL,VALUEI(1,2),DATA,STS_M_42,STS_E_42
*VFILL,VALUEI(1,3),DATA,(STS_M_42/57.457),(STS_E_42/51.073)
*VFILL,VALUEII(1,1),DATA,57.457,51.073
*VFILL,VALUEII(1,2),DATA,STS_M_82,STS_E_82
*VFILL,VALUEII(1,3),DATA,(STS_M_82/57.457),(STS_E_82/51.073)
/COM,STS_M_42 = STRESS AT MID-LENGTH USING ELEMENT 42
/COM,STS_E_42 = STRESS AT FIXED END USING ELEMENT 42
/COM,STS_M_82 = STRESS AT MID-LENGTH USING ELEMENT 82
/COM,STS_E_82 = STRESS AT FIXED END USING ELEMENT 82
/COM,
/OUT, EX4_5, out
/COM,-------------------  EX4.5 RESULTS COMPARISON ---------------------
/COM,
/COM,RESULTS FOR PLANE42:
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
*VWRITE,LABEL(1,1),LABEL(1,2),VALUEI(1,1),VALUEI(1,2),VALUEI(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,
/COM,RESULTS FOR PLANE82:
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
*VWRITE,LABEL(1,1),LABEL(1,2),VALUEII(1,1),VALUEII(1,2),VALUEII(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST, EX4_5, out