ex4.6.txt

通过实例详细介绍Ansys在实际工程中的应用

!4.6  纯弯曲悬臂曲梁的二维静力分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)设置工程选项，定义分析类型，单元类型和材料参数
/FileName,EX4.6
/PREP7
smrt,off
/TITLE, EX4.6, BENDING OF A CURVED BEAM
C***    THEORY OF ELASTICITY, TIMOSHENKO & GOODIER, 3RD ED., P.78
ANTYPE,STATIC
ET,1,PLANE2,,,3
ET,2,BEAM3
R,1,25.4
R,2,1.0,1,1.0
MP,EX,1,68950
MP,NUXY,1,0.25
! (2)在柱坐标系下定义曲梁上的4个关键点,自由端处的线,通过线单元划分生成梁单元
CSYS,1
K,1,89
K,2,89,90
KGEN,2,1,2,1,25.4
L,2,4
LESIZE,1,,,4
TYPE,2
REAL,2
LMESH,1
! (3)过关键点定义曲梁的内侧和外侧圆弧线，过点定义曲梁面区域，面单元划分后得到有限元模型
L,1,2
LESIZE,2,,,25
L,3,4
LESIZE,3,,,25
ESIZE,,4
A,1,2,4,3
AATT,1,1,1
/DEVICE,VECTOR,1
AMESH,1
! (4)通过关键点定义位移约束和荷载
NROTAT,ALL
DK,1,ALL,,,1
DK,3,UY,,,1
FK,2,FY,452
FK,4,FY,-452
FINISH
! (5)进入求解模块求解
/SOLU
SOLVE
FINISH
! (6)在后处理模块中显示指定结点位置的应力计算结果
/POST1
RSYS,1
NSEL,R,LOC,X,89
NSEL,U,LOC,Y,90
PRNSOL,S,COMP
NSORT,S,Y
*GET,SI,SORT,,MAX
NSEL,ALL
NSEL,R,LOC,X,114
NSEL,U,LOC,Y,90
PRNSOL,S,COMP
NSORT,S,Y
*GET,SO,SORT,,MIN
/DEVICE,VECTOR,0
PLNSOL,S,Y
! (7)定义数组，将计算结果保存到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'INR STR ','OTR STR '
LABEL(1,2) = '(MPa)','(MPa)'
*VFILL,VALUE(1,1),DATA,4.655,-3.948
*VFILL,VALUE(1,2),DATA,SI,SO
*VFILL,VALUE(1,3),DATA,ABS(SI/4.655),ABS(SO/3.948)
/COM
/OUT, EX4_6, out
/COM,-------------------  EX4.6 RESULTS COMPARISON -------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST, EX4_6, out