ex3.4.txt

通过实例详细介绍Ansys在实际工程中的应用

!3.4  平面刚架的平面外失稳
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定义工程选项,定义节点位置
/FileName, EX3.4
/TITLE, EX3.4, LATERAL BUCKLING OF RIGHT-ANGLE FRAME
! Ref[28] J.C. SIMO, L. VU-QUOC, "THREE-DIMENSIONAL FINITE-STRAIN ROD
! MODEL",PART II CMAME, VOL 58, 1986, PP 79-116
/PREP7
N,1,,6096
N,21,6096,6096
N,41,6096,0
FILL,1,21
FILL,21,41
N,101,3048,9144
N,201,9144,3048
! (2)定义单元和截面几何参数,材料参数
SECNUM,1
ET,1,BEAM188
*DO,I,1,20,1
     E,I,I+1,101
*ENDDO
*DO,I,21,40,1
     E,I,I+1,201
*ENDDO
SECTYPE,1,BEAM,ASEC
SECDATA,11613,5.61868e8,0.0,224747,0.0,898989.1
MP,EX,1,491.2105
MP,NUXY,1,0.3
FINISH
! (3)设置求解选项,施加位移约束后求解小扰动力作用情况
/SOLU
NLGEOM,ON
NSUBST,2
D,1,ALL
F,41,FZ,1.0E-3
/OUT,SCRATCH,
SOLVE
/OUT
! (4)设置求解选项,施加位移约束后求解面内力作用发生平面弯曲的情况
OUTRES,ALL,ALL
ARCLEN,ON
ARCTRM,U,1524,41,UZ
F,41,FX,6.6057
NSUBST,10
/OUT,SCRATCH,
SOLVE
/OUT
FINISH
! (5)在时间历程后处理模块中,显示力和变形的关系
/POST26
/AXLAB,X,TIP DISPLACEMENT
/AXLAB,Y,END FORCE
NSOL,2,41,U,Z,DISP
RFORCE,3,1,F,X,FORCE
PROD,4,3, , ,FORCE , , ,-1.0,1,1,
XVAR,2
/COM,   THE LOAD DEFLECTION CURVE SHOWN IN  EX3.4.GRPH
/COM,   SHOW A CRITICAL LOAD OF APPROX. 1.09
PRVAR,2,4
PLVAR,4
FINISH
! (6)在一般后处理模块中,计算固定端处的反力
/POST1
SET,2,7,1
NSEL,S,LOC,X,0
FSUM
*GET,CP1,FSUM,,ITEM,FX
! (7)将计算结果输出到文件
*DIM,LABEL1,CHAR,1
*DIM,VALUE1,,1,3
LABEL1(1) = 'FX_CRLD'
*VFILL,VALUE1(1,1),DATA,4.849
*VFILL,VALUE1(1,2),DATA,ABS(CP1)
*VFILL,VALUE1(1,3),DATA,ABS(CP1/4.849)
/OUT, EX3_4, out
/COM,
/COM,-------------------  EX3.4  RESULTS COMPARISON ---------------------
/COM,
/COM,BEAM188              |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),VALUE1(1,3)
(1X,A15,'     ',F10.3,'     ',F10.3,'     ',1F5.3)
/OUT
FINISH
! (8)重新用三维二次有限变形梁单元BEAM189完成同样的分析,首先设置绘图选项
/CLEAR,NOSTART
/TRIAD,OFF
/PLOPTS,LOGO,0
/PLOPTS,INFO,2
/PLOPTS,WP,0
/RGB,INDEX,100,100,100,0
/RGB,INDEX,80,80,80,13
/RGB,INDEX,60,60,60,14
/RGB,INDEX,0,0,0,15
! (9)在前处理模块中定义节点
/PREP7
N,1,,6096
N,21,6096,6096
N,41,6096,0
FILL,1,21
FILL,21,41
N,101,3048,9144
N,201,9144,3048
! (10) 定义单元和截面几何参数,材料参数
SECNUM,1
ET,1,BEAM189
*DO,I,1,10,1
   I0=(I-1)*2+1
   E,I0,I0+2,I0+1,101
*ENDDO
*DO,I,11,20,1
   I0=(I-1)*2+1
   E,I0,I0+2,I0+1,201
*ENDDO
! (11)定义截面几何参数
SECTYPE,1,BEAM,ASEC
SECDATA,11613,5.61868e8,0.0,224747,0.0,898989.1
MP,EX,1,491.2105
MP,NUXY,1,0.3
FINISH
! (12) 设置求解选项,施加位移约束后求解面内力作用发生平面弯曲的情况
/SOLU
NLGEOM,ON
NSUBST,2
D,1,ALL
F,41,FZ,1.0E-3
SOLVE
OUTRES,ALL,ALL
ARCLEN,ON
ARCTRM,U,1524,41,UZ
F,41,FX,6.6057
NSUBST,10
/VIEW,1,1,2,3
/ANG,1
/PBC,F,,1
/PBC,U,,1
/PBC,ROT,,1
/ESHAPE,70
EPLOT
/ESHAPE,0
/PBC,ALL,OFF
/OUT,SCRATCH,,,APPEND
SOLVE
/OUT
FINISH
! (13) 在时间历程后处理模块中,显示力和变形的关系
/POST26
/AXLAB,X,TIP DISPLACEMENT
/AXLAB,Y,END FORCE
NSOL,2,41,U,Z,DISP
RFORCE,3,1,F,X,FORCE
PROD,4,3, , , , , ,-1.0,1,1,
XVAR,2
PRVAR,2,4
PLVAR,4
FINISH
! (14) 在一般后处理模块中,计算固定端处的反力
/POST1
SET,2,7,1
NSEL,S,LOC,X,0
FSUM
*GET,CP2,FSUM,,ITEM,FX
! (15) 将计算结果输出到文件
*DIM,LABEL2,CHAR,1
*DIM,VALUE2,,1,3
LABEL2(1) = 'FX_CRLD'
*VFILL,VALUE2(1,1),DATA,4.849
*VFILL,VALUE2(1,2),DATA,ABS(CP2)
*VFILL,VALUE2(1,3),DATA,ABS(CP2/4.849)
! (16)显示最一个荷载步的变形情况
SET,LAST
/AUTO,1
ALLSEL
/VIEW,1,,,1
/ANG,1
PLDISP,1
/VIEW,1,,-1
PLDISP,1
! (17) 将计算结果输出到文件
/COM
/OUT, EX3_4, out,,APPEND
/COM,
/COM,BEAM189
/COM,
*VWRITE,LABEL2(1),VALUE2(1,1),VALUE2(1,2),VALUE2(1,3)
(1X,A15,'     ',F10.3,'     ',F10.3,'     ',1F5.3)
/COM,------------------------------------------------- ------------
/OUT
FINISH
*LIST, EX3_4, out