ex3.2.txt

通过实例详细介绍Ansys在实际工程中的应用

!3.2  利用实体单元计算压杆稳定性
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)设置工程选项, 单元类型, 实常数和材料参数
/FILENAME, EX3.2
/PREP7
/TITLE, EX3.2, BUCKLING OF A BAR WITH HINGED BY PLANE42 ELEMENT
C***    STR. OF MATL., TIMOSHENKO, PART 2, 3RD ED., PAGE 148
ET,1,PLANE42,,,3
R,1,12.7
MP,EX,1, 207000
MP,PRXY,,0.3
! (2) 定义节点和单元
N,1
N,11,,2540
FILL
! NGEN, ITIME, INC, NODE1, NODE2, NINC, DX, DY, DZ, SPACE
NGEN,2,11,1,11,,12.7
E,12,13,2,1
EGEN,10,1,1
FINISH
! (3) 定义求解选项, 位移约束和荷载力, 并开始静力分析的求解
/SOLU
PSTRES,ON
D,1,ALL,,,12,11
F,11,FY,-.5,,22,11
OUTPR,,1
SOLVE
FINISH
! (4)再次进入求解模块, 进行屈曲分析
/SOLU
ANTYPE,BUCKLE
BUCOPT,SUBSP,1
MXPAND,1
SOLVE
! (5)提取计算结果
*GET,FCR1,MODE,1,FREQ
*status,parm
! (6) 定义数组变量, 将计算结果输出到文件
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fcr '
LABEL(1,2) = '(N)'
*VFILL,VALUE(1,1),DATA,171.46
*VFILL,VALUE(1,2),DATA,FCR1
*VFILL,VALUE(1,3),DATA,ABS(FCR1/171.46)
/COM
/OUT, EX3_2, out
/COM,-------------------  EX3.2 RESULTS COMPARISON -------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM, Subspace Solution
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
! (7)改用其它特征值求解方法
/SOLU
BUCOPT,LANB ,1
SOLVE
! (8)显示计算结果
*GET,FCR2,MODE,1,FREQ
*status,parm
! (9)定义数组变量, 将计算结果输出到文件
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'Fcr '
LABEL(1,2) = '(N)'
*VFILL,VALUE(1,1),DATA,171.46
*VFILL,VALUE(1,2),DATA,FCR2
*VFILL,VALUE(1,3),DATA,ABS(FCR2/171.46)
/COM
/OUT, EX3_2,out,,APPEND
/COM,
/COM, Block-Lanczos Solution
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST, EX3_2, out