ex3.3.txt

通过实例详细介绍Ansys在实际工程中的应用

!3.3  悬臂压杆的过曲屈分析
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)设置工程选项, 单元类型, 实常数和材料参数
/FileName, EX3.3
/PREP7
/TITLE, EX3.3, LARGE DEFLECTIONS OF A BUCKLED BAR (THE ELASTICA)
C***    THEORY OF ELASTIC STABILITY, TIMOSHENKO AND GERE, 2ND ED., PAGE 78
ANTYPE,STATIC
NLGEOM,ON
ET,1,BEAM3,,,,,,,1
R,1,161.29,2167.86,12.7
MP,EX,1,207000
MP,PRXY,,0.3
! (2) 定义节点和单元
N,1
N,11,,2540
FILL
E,1,2
EGEN,10,1,1
FINISH
! (3) 设置求解选项,位移约束和荷载,开始求解
/SOLU
SOLCONTROL,0
NEQIT,250
OUTPR,BASIC,LAST
D,1,ALL
FCR=-171.5
PI=3.14159265359
F,11,FY,FCR*1.015
F,11,FX,1
SOLVE
! (4)增加荷载,继续求解
FDEL,11,FX
F,11,FY,FCR*1.063
SOLVE
F,11,FY,FCR*1.152
SOLVE
F,11,FY,FCR*1.293
SOLVE
F,11,FY,FCR*1.518
SOLVE
F,11,FY,FCR*1.884
SOLVE
FINISH
! (5)在一般后处理模块中,绘制后屈曲构型图
/POST1
/USER
/FOCUS,,1270,1270
/DIST,,1397
/DSCALE,,1
SET,1,0
PLDISP,1
/NOERASE
SET,2,0
PLDISP
SET,3,0
PLDISP
*GET,UX3,NODE,11,U,X
*GET,UY3,NODE,11,U,Y
*GET,ROT3A,NODE,11,ROT,Z
SET,4,0
PLDISP
*GET,UX4,NODE,11,U,X
*GET,UY4,NODE,11,U,Y
*GET,ROT4A,NODE,11,ROT,Z
SET,5,0
PLDISP
*GET,UX5,NODE,11,U,X
*GET,UY5,NODE,11,U,Y
*GET,ROT5A,NODE,11,ROT,Z
SET,6,0
PLDISP
*GET,UX6,NODE,11,U,X
*GET,UY6,NODE,11,U,Y
*GET,ROT6A,NODE,11,ROT,Z
*status,parm
! (6)将第3荷载步的计算结果保存到数组变量,然后输出到文件EX3_3.out
*SET,ROT6,(180*ROT6A/PI)
*SET,ROT5,(180*ROT5A/PI)
*SET,ROT4,(180*ROT4A/PI)
*SET,ROT3,(180*ROT3A/PI)
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'ROTZ ',' UX',' UY'
LABEL(1,2) = '(DEG)',' (mm)',' (mm)'
*VFILL,VALUE(1,1),DATA,-60,1506.22,-657.86
*VFILL,VALUE(1,2),DATA,ROT3,UX3,UY3
*VFILL,VALUE(1,3),DATA,ABS(ROT3/60),ABS(UX3/1506.22),ABS(UY3/657.86)
/COM
/OUT, EX3_3, out
/COM,-------------------  EX3.3  RESULTS COMPARISON -------------
/COM,
/COM,    F=197.56 N  |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.3)

/OUT
! (7)将第4荷载步的计算结果保存到数组变量,然后追加输出到文件EX3_3.out
/NOPR
*VFILL,VALUE(1,1),DATA,-80,1826.26,-1117.6
*VFILL,VALUE(1,2),DATA,ROT4,UX4,UY4
*VFILL,VALUE(1,3),DATA,ABS(ROT4/80),ABS(UX4/1826.26),ABS(UY4/1117.6)
/GOPR
/COM
/OUT, EX3_3,out,,APPEND
/COM,-------------------  EX3.3 RESULTS COMPARISON -------------
/COM,
/COM,    F=221.743 N  |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.3)

/OUT
! (8)将第5荷载步的计算结果保存到数组变量,然后追加输出到文件EX3_3.out
/NOPR
*VFILL,VALUE(1,1),DATA,-100,2011.68,-1653.54
*VFILL,VALUE(1,2),DATA,ROT5,UX5,UY5
*VFILL,VALUE(1,3),DATA,ABS(ROT5/100),ABS(UX5/2011.68),ABS(UY5/1653.54)
/GOPR
/COM
/OUT, EX3_3,out,,APPEND
/COM,-------------------  EX3.3 RESULTS COMPARISON -------------
/COM,
/COM,    F=260.328 N  |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.3)

/OUT
! (9) 将第6荷载步的计算结果保存到数组变量
/NOPR
*VFILL,VALUE(1,1),DATA,-120,2039.62,-2227.58
*VFILL,VALUE(1,2),DATA,ROT6,UX6,UY6
*VFILL,VALUE(1,3),DATA,ABS(ROT6/120),ABS(UX6/2039.62),ABS(UY6/2227.58)
/GOPR
/COM
! (10) 将第6荷载步的计算结果,追加输出到文件EX3_3.out
/OUT, EX3_3,out,,APPEND
/COM,-------------------  EX3.3  RESULTS COMPARISON -------------
/COM,
/COM,    F=323.098 N  |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.3)

/OUT
FINISH
*LIST, EX3_3, out